# $Id: PKGBUILD 116238 2011-03-22 20:34:48Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=eog
pkgver=2.91.92
pkgrel=1
pkgdesc="Eye of Gnome: An image viewing and cataloging program"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gnome-desktop' 'libexif' 'lcms' 'desktop-file-utils' 'exempi'
         'dbus-glib' 'libpeas' 'librsvg' 'gnome-icon-theme')
makedepends=('gtk-doc' 'intltool')
install=eog.install
groups=('gnome-extra')
options=('!emptydirs' '!libtool')
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('047119ac7152037acec3090f710e4a6f21e55103030805c44da6a46dcb275934')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-scrollkeeper
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  # remove it from Xfce menu that ships its own thingy
  echo "NotShowIn=XFCE" >> ${pkgdir}/usr/share/applications/eog.desktop
}