# $Id$
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
_pkgname=cdrtools
pkgname=cdrtools-libre
pkgver=3.01a12
pkgrel=1
pkgdesc="Original cdrtools supporting CD, DVD and BluRay burning (without nonfree apple_driver utility)"
arch=('i686' 'x86_64' 'mips64el')
url="http://cdrecord.berlios.de/private/cdrecord.html"
license=('CDDL')
depends=('acl')
replaces=('cdrtools')
conflicts=('cdrtools' 'cdrkit')
provides=("cdrtools=${pkgver}" 'cdrkit')
options=(!makeflags)
backup=('etc/default/cdrecord' 'etc/default/rscsi')
install=cdrtools.install
source=(http://ftp.berlios.de/pub/cdrecord/alpha/cdrtools-$pkgver.tar.bz2)
md5sums=('563d80a7102175bea3e41fbfc269b914')

build() {
  cd "$srcdir"/cdrtools-${pkgver%%a*}

  # Remove nonfree apple_driver utility
  rm -rvf mkisofs/{apple_driver{.c,.8,.mk,_man.mk},README.hfs_boot,Rhfs_boot.mk}
  sed -i -e '/apple_driver/d' mkisofs/Makefile
  sed -i -e '/README.hfs_boot/d' pkgdefs/CSW/CSWcdrtools/prototype
  sed -i -e '/README.hfs_boot/d' pkgdefs/OCSW/CSWcdrtools/prototype
  sed -i -e '/README.hfs_boot/d' vms/vms_name_fix.sh

  sed -i 's|/opt/schily|/usr|g' DEFAULTS/Defaults.linux
  sed -i 's|DEFINSGRP=.*|DEFINSGRP=root|' DEFAULTS/Defaults.linux
  
  export GMAKE_NOWARN=true
  make INS_BASE=/usr INS_RBASE=/
}

package() {
  cd "$srcdir"/cdrtools-${pkgver%%a*}

  export GMAKE_NOWARN=true
  make INS_BASE=/usr INS_RBASE=/ DESTDIR="$pkgdir" install
  rm -rf "$pkgdir"/usr/include
  rm -rf "$pkgdir"/usr/lib/{*.a,profiled}

  # autoload 'sg' module needed by cdrecord
  install -d -m755 "$pkgdir"/usr/lib/modules-load.d/
  echo sg > "$pkgdir"/usr/lib/modules-load.d/cdrecord.conf

  # create symlinks for cdrkit compatibility
  cd "$pkgdir"/usr/bin
  ln -s cdrecord wodim
  ln -s readcd readom
  ln -s mkisofs genisoimage
  ln -s cdda2wav icedax
}

# vim:set ts=2 sw=2 et: