# $Id: PKGBUILD 145815 2012-01-02 10:16:37Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=evolution-exchange
pkgver=3.2.1
pkgrel=2
pkgdesc="Ximian Connector Exchange plugin for Evolution"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.ximian.com"
depends=('evolution-data-server' 'gtkhtml4' 'gnome-desktop')
makedepends=('intltool' 'evolution')
options=('!libtool' '!emptydirs')
install=evolution-exchange.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('d9bebd1ab252e8568409fb1c50ba5a8f0c8236a8abf72ba697c95f9134d4cd9c')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
      --libexecdir=/usr/lib/evolution --disable-static \
      --with-libdb=/usr --with-krb5=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -m755 -d "$pkgdir/usr/share/gconf/schemas"
  gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" --domain evolution-exchange-3.2 $pkgdir/etc/gconf/schemas/*.schemas
  rm -f $pkgdir/etc/gconf/schemas/*.schemas
}