# $Id: PKGBUILD 160710 2012-06-04 09:14:43Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>

pkgname=gnome-session
pkgver=3.4.2
pkgrel=2
pkgdesc="The GNOME Session Handler"
arch=(i686 x86_64)
license=('GPL' 'LGPL')
depends=('libsystemd' 'consolekit' 'dconf' 'gconf' 'gsettings-desktop-schemas' 'gtk3'
         'hicolor-icon-theme' 'json-glib' 'libgl' 'libsm' 'libxtst' 'polkit-gnome'
         'startup-notification' 'upower')
makedepends=('intltool' 'mesa' 'xtrans')
options=('!emptydirs')
install=gnome-session.install
url="http://www.gnome.org"
groups=('gnome')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
        gnome-session-3.3.1-llvmpipe.patch timeout.patch)
sha256sums=('6c2cbc86b63bb4869f4f95e7771ec6eee0c02965b732d634de5c8122607c4356'
            '59ea58012febe48a67dabd944dc638400637ad4d296d63b63b585f10eea4f85e'
            '1942c8144711cf4bc0e776edd366579849e266a446b48cca0205d7ab82241782')

build() {
  cd $pkgname-$pkgver

  # Allow software rendering
  patch -Np1 -i ../gnome-session-3.3.1-llvmpipe.patch

  # Increase timeout, for slow machines
  patch -Np1 -i ../timeout.patch

  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --libexecdir=/usr/lib/gnome-session \
      --disable-schemas-compile --enable-systemd
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}