# $Id: PKGBUILD 166896 2012-09-21 02:03:06Z allan $
# Maintainer: Dan McGee <dan@archlinux.org>

pkgname=libarchive
pkgver=3.0.4
pkgrel=2
pkgdesc="library that can create and read several streaming archive formats"
arch=('i686' 'x86_64')
url="http://libarchive.googlecode.com/"
license=('BSD')
depends=('zlib' 'bzip2' 'xz>=5.0.0' 'acl' 'openssl>=1.0.0' 'expat')
source=("https://github.com/downloads/libarchive/libarchive/libarchive-${pkgver}.tar.gz"
        libarchive-3.0.x-fix-mtree-writer.patch)
md5sums=('af443ca9a10ddbcbf00f7ae34ca7fc16'
         '6d36a50a7282db6576bd1fbc23f08055')
sha256sums=('76e8d7c7b100ec4071e48c1b7d3f3ea1d22b39db3e45b7189f75b5ff4df90fac'
            'f0081c0d7d7875fc91c683b14fe4876d56b6585f45be9181c755eba4b522f5b9')


build() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i $srcdir/libarchive-3.0.x-fix-mtree-writer.patch
  ./configure --prefix=/usr --without-xml2
  make
}

check() {
  cd "$srcdir/$pkgname-$pkgver"

  make check
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -D -m644 COPYING "$pkgdir"/usr/share/licenses/libarchive/COPYING
}