blob: dad8c5443bfa8652f8a7b2eb95eb4f58d4c7e1c5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 113676 2014-06-27 18:32:24Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Sébastien Luttringer
# Contributor: SpepS <dreamspepser at yahoo dot it>
# Contributor: Laszlo Papp <djszapi at archlinux us>
# Contributor: Donald Ephraim Curtis <dcurtis@gmail.com>
pkgname=lua-posix
pkgver=32
pkgrel=3
pkgdesc='POSIX library for Lua'
arch=('x86_64' 'i686')
url='https://github.com/luaposix/luaposix'
license=('MIT')
depends=('lua')
makedepends=('git' 'help2man' 'ldoc')
options=('!makeflags')
source=("$pkgname::git://github.com/luaposix/luaposix.git#tag=v$pkgver")
md5sums=('SKIP')
prepare() {
cd "$pkgname"
./bootstrap
}
build() {
cd "$pkgname"
./configure \
LUA=/usr/bin/lua \
--prefix=/usr \
--libdir=/usr/lib/lua/5.2 \
--datadir=/usr/share/lua/5.2 \
--docdir=/usr/share/doc/lua-posix
make
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|
