# Maintainer: Nicolas Reynolds <fauno@kiwwwi.com.ar>
#

_pkgname=binutils
_target=mips64el-unknown-linux-gnu
_sysroot=/usr/lib/cross-${_target}

pkgname=cross-${_target}-binutils
pkgver=2.21
pkgrel=1
pkgdesc="A set of programs to assemble and manipulate binary and object files for cross ${_target}"
license=('GPL')
arch=('i686' 'x86_64')
source=(http://ftp.gnu.org/gnu/$_pkgname/$_pkgname-$pkgver.tar.bz2)
groups=('cross-mips64el')
depends=('glibc>=2.13' 'zlib')
makedepends=('dejagnu')
options=('!libtool' '!distcc' '!ccache')

build() {
  cd ${srcdir}
  mkdir binutils-build
  cd binutils-build

  $srcdir/$_pkgname-$pkgver/configure \
      --prefix=$_sysroot \
      --target=$_target \
      --program-prefix=$_target- \
      --with-sysroot=$_sysroot \
      --disable-nls \
      --disable-werror 

  make
}

check() {
  cd ${srcdir}/binutils-build

  # do not abort on errors - manually check log files
  make -k -j1 check || true
}

package() {
  cd ${srcdir}/binutils-build
  make DESTDIR=${pkgdir} install
}
md5sums=('c84c5acc9d266f1a7044b51c85a823f5')