# Maintainer: Nicolas Reynolds <fauno@kiwwwi.com.ar>
#

_pkgname=gcc
_target=mips64el-unknown-linux-gnu
_sysroot=/usr/lib/cross-${_target}

pkgname=cross-${_target}-gcc1
pkgver=4.5.3
pkgrel=1
pkgdesc="The GNU C Compiler for $_target stage1"
arch=(i686 x86_64)
license=(GPL)
makedepends=("cross-${_target}-binutils")
options=(!strip)
source=(http://ftp.gnu.org/gnu/$_pkgname/$_pkgname-$pkgver/$_pkgname-$pkgver.tar.bz2)

build() {
    cd $srcdir
    export PATH="${_sysroot}/bin:$PATH"

    unset CFLAGS CXXFLAGS

    [[ $NOEXTRACT -eq 1 ]] || mkdir build
    cd build

# No bindir
    [[ $NOEXTRACT -eq 1 ]] || ../$_pkgname-$pkgver/configure \
        --prefix=$_sysroot \
        --target=$_target \
        --disable-bootstrap \
        --disable-nls \
        --without-headers \
        --with-newlib \
        --disable-shared \
        --disable-threads \
        --disable-libssp \
        --disable-libgomp \
        --disable-libmudflap \
        --enable-languages=c \
        --without-ppl \
        --without-cloog
    make
}

package() {
    cd $srcdir/build
    export PATH="${_sysroot}/bin:$PATH"

    make DESTDIR=$pkgdir install
}
md5sums=('8e0b5c12212e185f3e4383106bfa9cc6')