From 75e967745630c5f858701f4b81a5a2c3a82fc9a8 Mon Sep 17 00:00:00 2001
From: André Fabian Silva Delgado <emulatorman@parabola.nu>
Date: Wed, 23 Oct 2013 19:30:00 -0200
Subject: duplicity-nonprism: add new package for nonprism repo

---
 nonprism/duplicity-nonprism/PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 nonprism/duplicity-nonprism/PKGBUILD

(limited to 'nonprism')

diff --git a/nonprism/duplicity-nonprism/PKGBUILD b/nonprism/duplicity-nonprism/PKGBUILD
new file mode 100644
index 000000000..e185723f0
--- /dev/null
+++ b/nonprism/duplicity-nonprism/PKGBUILD
@@ -0,0 +1,48 @@
+# $Id: PKGBUILD 96718 2013-09-03 12:44:55Z lfleischer $
+# Maintainer: Kaiting Chen <kaitocracy@gmail.com>
+# Contributor: Aaron Schaefer <aaron@elasticdog.com>
+# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
+
+_pkgname=duplicity
+pkgname=duplicity-nonprism
+pkgver=0.6.22
+pkgrel=1
+pkgdesc='A utility for encrypted, bandwidth-efficient backups using the rsync algorithm, without python2-gdata recommendation.'
+arch=('i686' 'x86_64')
+url='http://www.nongnu.org/duplicity/'
+license=('GPL')
+depends=('gnupg' 'librsync' 'ncftp' 'python2-paramiko')
+optdepends=('lftp: FTPS backend'
+            'python2-boto: Amazon S3 backend'
+            'python2-gobject: GIO backend'
+            'gvfs: GIO backend'
+            'python2-httplib2: Ubuntu One backend'
+            'python2-oauthlib: Ubuntu One backend'
+            'rsync: rsync backend')
+replaces=$_pkgname
+conflicts=$_pkgname
+provides=$_pkgname=$pkgver
+source=("http://savannah.nongnu.org/download/$_pkgname/$_pkgname-$pkgver.tar.gz"{,.sig})
+md5sums=('5b035359a6bb7b2f3f3b9829c6c071e1'
+         'SKIP')
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+
+  # python2 fix
+  for file in $(find . -name '*.py' -print); do
+    sed -i 's_^#!.*/usr/bin/python$_#!/usr/bin/python2_' $file
+    sed -i 's_^#!.*/usr/bin/env.*python$_#!/usr/bin/env python2_' $file
+  done
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  # fix broken documentation permissions until upstream does (FS#27301)
+  chmod 644 "$pkgdir/usr/share/man/man1/$_pkgname.1"
+  chmod 644 "$pkgdir/usr/share/man/man1/rdiffdir.1"
+  chmod 644 "$pkgdir/usr/share/doc/$_pkgname-$pkgver"/*
+}
-- 
cgit v1.2.3-54-g00ecf