# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Initial contributor: flixie <69one@gmx.net>
# Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>
pkgname=luxrender-art
pkgver=1.0rc4
_pkgver=0b4c3e188707
pkgrel=1
pkgdesc='Rendering system for physically correct, unbiased image synthesis'
arch=(
  i686
  x86_64
  mips64el
)
url=http://www.${pkgname%-art}.net/
license=(
  GPL
)
depends=(
  boost-libs
  freeimage
  openexr
  libcl-libre
)
optdepends=(
  'luxblend25: Blender exporter'
  'python: Python interface (pylux)'
  'qt: Qt GUI'
)
makedepends=(
  cmake
  boost
  qt
  ${pkgname::3}rays-art=$pkgver
  python
  opencl-headers
)
conflicts=(
  ${pkgname%-art}
)
provides=(
  ${pkgname%-art}=$pkgver
)
source=(
  https://bitbucket.org/${pkgname%-art}/${pkgname::3}/get/$_pkgver.tar.bz2
  boost_1.50_fix.diff
)
md5sums=(
  54ff625a7833541c3cff5f0a77a93863
  8c7774bb0c97aadd77d9e665d8fa4aab
)

build() {
  cd $srcdir/${pkgname%-art}-${pkgname::3}-$_pkgver

  # fix for boost 1.50
  # the boost::TIME_UTC has been renamed due to the conflict with C++11
  patch -Np1 < $srcdir/boost_1.50_fix.diff || true

  export CXXFLAGS='$CXXFLAGS -lpthread'
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
    -DLUXRAYS_DISABLE_OPENCL=ON \
    -DPYTHON_CUSTOM=ON \
    -DPYTHON_LIBRARIES=/usr/lib/libpython3.2mu.so \
    -DPYTHON_INCLUDE_PATH=/usr/include/python3.2mu \
    .
  make
}

package() {
  cd $srcdir/${pkgname%-art}-${pkgname::3}-$_pkgver
  make DESTDIR=$pkgdir install

  # fix library path on x86_64
  [ $CARCH = x86_64 ] && mv $pkgdir/usr/lib64 $pkgdir/usr/lib

  #install pylux
  install -D -m644 pylux.so $pkgdir/usr/lib/python3.2/pylux.so
}