# $Id: PKGBUILD 283325 2016-12-15 10:41:32Z arojas $
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org> 
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=ark
pkgver=16.12.0
pkgrel=1.parabola1
pkgdesc='Archiving Tool, with unar support'
arch=(i686 x86_64 armv7h)
url='http://kde.org/applications/utilities/ark/'
license=(GPL)
depends=(kparts kpty libarchive hicolor-icon-theme)
makedepends=(extra-cmake-modules kdoctools python)
optdepends=('p7zip: 7Z format support' 'zip: ZIP compression support' 'unzip: ZIP format support' 'unar: RAR format support')
conflicts=(kdeutils-ark)
replaces=(kdeutils-ark)
groups=(kde-applications kdeutils)
source=("http://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
        'libre.patch')
md5sums=('4c0e09b5ec61bda3e722f446496f8cb3'
         'SKIP'
         '24dd92f19aba961b01d6975af12f9b53')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>

prepare() {
  mkdir -p build
  cd $pkgname-$pkgver
  patch -p1 -i ../libre.patch
  rm -rv plugins/clirarplugin
}

build() { 
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}