# $Id$
# Maintainer (Arch): AndyRTR <andyrtr at archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=beanshell2
pkgver=2.1.8
pkgrel=1.parabola1
pkgdesc="Small, free, embeddable, source level Java interpreter with object based scripting language features written in Java"
arch=('any')
url="https://code.google.com/p/beanshell2/"
license=('LGPL')
depends=('java-runtime')
provides=('bsh' 'beanshell')
conflicts=('beanshell')
replaces=('beanshell')
makedepends=('apache-ant' 'java-commons-bsf2' 'javacc' 'tomcat7')
source=("https://beanshell2.googlecode.com/svn/branches/v2.1/downloads/bsh-${pkgver}-src.zip"
        'bsh.sh'
        'bsh-desktop.sh'
        'bsh-window.sh')
sha1sums=('c3d5f844316051ebba1f57c226a9b3466138d9d4'
          'dcf00fb8f445de72da1e77c42cc2d759291af5f1'
          '4188603afd4834d73b91e5006ef2476a83954a04'
          '5a125e0eb68d825d437f6c0c6a5d17afa2d76b93')

prepare() {
  cd "${srcdir}/BeanShell2-${pkgver}"

  rm -v lib/*.jar
  rm -rv downloads
  ln -s /usr/share/java/bsf2.jar lib/
  ln -s /usr/share/java/javacc.jar lib/
  ln -s /usr/share/java/tomcat7/servlet-api.jar lib/servlet.jar
  sed -i 's/ 1\.8/ 1\.9/g' build.xml
  sed -i 's/"1\.8/"1\.9/g' build.xml
}

build() {
  cd "${srcdir}/BeanShell2-${pkgver}"
  ant dist
}

check() {
  cd "${srcdir}/BeanShell2-${pkgver}"
  ant test
}

package() {
  cd "${srcdir}/BeanShell2-${pkgver}/dist"
  local artifact
  for artifact in $(printf '%s\n' *.jar|sed 's/-[0-9b.]*\.jar$//'); do
    install -Dm644 ${artifact}-${pkgver}.jar "${pkgdir}/usr/share/java/${artifact}.jar"
  done
  local exe
  for exe in bsh bsh-desktop bsh-window; do
    install -Dm755 "${srcdir}/${exe}.sh" "${pkgdir}/usr/bin/${exe}"
  done
}