# $Id: PKGBUILD 157442 2012-04-28 11:27:45Z allan $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Alexander Fehr <pizzapunk gmail com>

_pkgname=cdrkit
pkgname=cdrkit-libre
pkgver=1.1.11
pkgrel=2.3
pkgdesc="Suite of programs for CD/DVD recording, ISO image creation, and audio CD extraction (without nonfree apple_driver utility)"
arch=('i686' 'x86_64')
url="http://cdrkit.org/"
license=('GPL2')
depends=('file' 'bzip2')
optdepends=('perl: for dirsplit')
makedepends=('cmake')
provides=("cdrkit=${pkgver}")
conflicts=('cdrkit')
replaces=('cdrkit')
source=(http://cdrkit.org/releases/$_pkgname-$pkgver.tar.gz)
md5sums=('efe08e2f3ca478486037b053acd512e9')

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  # Remove nonfree apple_driver utility
  rm -rvf {doc/genisoimage/README.hfs_boot,genisoimage/apple_driver.{c,8}}

  make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make PREFIX="$pkgdir/usr" install

  # Make symlinks for cdrtools compatibility
  cd "$pkgdir/usr/bin"
  ln -s wodim cdrecord
  ln -s readom readcd
  ln -s genisoimage mkisofs
  ln -s genisoimage mkhybrid
  ln -s icedax cdda2wav

  cd "$pkgdir/usr/share/man/man1"
  ln -s wodim.1 cdrecord.1
  ln -s readom.1 readcd.1
  ln -s genisoimage.1 mkisofs.1
  ln -s genisoimage.1 mkhybrid.1
  ln -s icedax.1 cdda2wav.1
}