# $Id: PKGBUILD 141630 2015-09-26 02:40:42Z fyan $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=gloobus-preview
pkgver=0.4.5.333
pkgrel=2.parabola1
pkgdesc="GNOME application designed to enable a full screen preview of any kind of file, with libarchive support"
arch=('i686' 'x86_64')
url="http://gloobus.net/"
license=('GPL')
depends=('gst-plugins-base' 'gtksourceview3' 'poppler-glib' 'python-dbus' 'python-gobject')
makedepends=('boost' 'bzr' 'djvulibre' 'libgxps' 'libspectre')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
optdepends=('djvulibre: Preview DjVu documents'
            'gst-libav: Extra media codecs'
            'gst-plugins-bad: Extra media codecs'
            'gst-plugins-good: Extra media codecs'
            'gst-plugins-ugly: Extra media codecs'
            'imagemagick: Support for more image formats'
            'libgxps: Preview XPS documents'
            'libspectre: Preview PostScript documents'
            'unoconv: Preview LibreOffice compatible documents')
install=$pkgname.install
source=($pkgname-$pkgver::bzr+http://bazaar.launchpad.net/~gloobus-dev/gloobus-preview/last_working_branch#revision=333
	gloobus-preview-usr-bsdtar-for-rar.patch)
md5sums=('SKIP'
         'f605aab1153b7dcd136a16264182a526')

prepare() {
  cd $pkgname-$pkgver

  # Use bsdtar (libarchive) for RAR.
  patch -Np1 -i "$srcdir/gloobus-preview-usr-bsdtar-for-rar.patch"
}

build() {
  cd $pkgname-$pkgver
  ./autogen.sh --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}