# $Id: PKGBUILD 111780 2014-05-24 14:01:37Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

_pkgname=gnome-boxes
pkgname=gnome-boxes-libre
pkgver=3.12.2
pkgrel=1
pkgdesc="Simple GNOME 3 application to access remote or virtual systems, without nonfree system logos"
arch=('i686' 'x86_64')
url="https://wiki.gnome.org/Apps/Boxes"
license=('LGPL')
provides=($_pkgname=$pkgver)
conflicts=($_pkgname)
replaces=($_pkgname)
depends=('clutter-gtk' 'gtk-vnc' 'libosinfo' 'libsoup' 'libvirt-glib' 'spice-gtk3'
         'libtracker-sparql' 'qemu' 'cdrkit' 'libcdio' 'mtools' 'dconf'
         'gnome-icon-theme' 'gnome-themes-standard')
makedepends=('gobject-introspection' 'intltool' 'itstool' 'spice-protocol' 'vala')
install=$_pkgname.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$_pkgname/${pkgver%.*}/$_pkgname-$pkgver.tar.xz
        libre.patch)
sha256sums=('88d52ba44eba27aa1b546fb648e291d0b7b7bc3df948efd6d44ac7342782ed4f'
            '2a93935ba94b9f327645a92f11d1a3d23cbeab8e5c800e414c6762181f51d4c0')

prepare() {
  cd $_pkgname-$pkgver

  patch -Np1 -i "$srcdir/libre.patch"
}

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$_pkgname \
              --disable-static --disable-schemas-compile --enable-smartcard
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}