# $Id: PKGBUILD 112452 2014-06-02 10:30:28Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): TingPing <tingping@tingping.se>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=hexchat
pkgname=hexchat-libre
pkgver=2.10.0
pkgrel=1
pkgdesc='A popular and easy to use graphical IRC (chat) client, without nonfree browser reference (Parabola rebranded)'
arch=('i686' 'x86_64' 'mips64el')
url='http://hexchat.github.io/'
license=('GPL')
depends=('dbus-glib' 'desktop-file-utils' 'gtk2' 'libcanberra' 'libnotify' 'libproxy' 'pciutils')
makedepends=('intltool' 'iso-codes' 'perl' 'python')
optdepends=('enchant: Spell check'
            'perl: Perl plugin'
            'python: Python plugin')
install="${_pkgname}.install"
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
source=("http://dl.hexchat.org/${_pkgname}/${_pkgname}-${pkgver}.tar.xz")
sha256sums=('a0247f1e12379154d0719d9c6861dc22817b588562653bb9d3626863d8eca916')

build() {
  cd ${_pkgname}-${pkgver}

# Rebrand to Parabola
  sed -i 's#ArchLinux#Parabola GNU/Linux-libre#' plugins/sysinfo/parse.c

# Remove nonfree browser references
  sed -i '\|NAME Open Link| s|Firefox|Iceweasel|' src/common/hexchat.c
  sed -i '\|NAME Open Link| s|firefox -private %s\\n\\n";|iceweasel -private %s\\n\\n"\\\n		"NAME Open Link in Private Icecat Window\\n"		"CMD !icecat -private %s\\n\\n";|' src/common/hexchat.c

  ./configure --prefix='/usr' --enable-{python='python3.4',textfe}
  make
}

package() {
  cd ${_pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: