# Maintainer : Márcio Silva <coadde@adinet.com.uy>
# Maintainer : André Silva <andre.paulista@adinet.com.uy>

# We're getting this from Debian Sid
_debname=iceape
_debver=2.7.4
_debrel=1
_debrepo=http://ftp.debian.org/debian/pool/main/
debfile() { echo $@|sed -r 's@(.).*@\1/&/&@'; }

_pkgname=${_debname}
pkgname=${_debname}-libre
pkgver=${_debver}
pkgrel=1
pkgdesc="A libre version of Debian Iceape, the internet suite based on Mozilla Seamonkey."
arch=('i586' 'i686' 'x86_64' 'mips64el')
license=('GPL2' 'MPL' 'LGPL')
depends=('alsa-lib' 'dbus-glib' 'desktop-file-utils' 'gtk2' 'hunspell' 'libevent' 'libnotify' 'libvpx' 'libxt' 'mime-types' 'mozilla-common' 'mozilla-searchplugins' 'nss' 'sqlite' 'startup-notification')
makedepends=('unzip-libre' 'zip' 'pkg-config' 'python2' 'python2-ply' 'librsvg' 'wireless_tools' 'yasm' 'mesa' 'autoconf2.13' 'quilt')
replaces=('mozilla' 'seamonkey')
conflicts=('seamonkey')
provides=('seamonkey')
install=$_pkgname.install
url="http://packages.debian.org/source/sid/${_pkgname}"
source=("${_debrepo}/`debfile ${_debname}`_${_debver}.orig.tar.bz2"
        "${_debrepo}/`debfile ${_debname}`_${_debver}-${_debrel}.debian.tar.gz"
        mozconfig
        ${_pkgname}.desktop
        ${_pkgname}-2.0-lang.patch
        gcc47.patch
        clrf.patch
        gnuzilla-addons.patch)
md5sums=('aedc7546db1fdc50cc9c5f21a7ad6138'
         '46908aec059166ac48592a8119badf3e'
         '3cbbe74f467e6d23f7fde508b30c139f'
         '0e981f6ce32fbe6407fe18a591bd3b41'
         '25b6fe16ac24cd5c852213e5c1adb272'
         '94d5cd599ccc4438f192d8daabf98b6a'
         'c395d443a8c4c16880c7322bcf174743'
         'a1da44f87b8f86fd5a810bbe14e983e8')

build() {
  export QUILT_PATCHES=debian/patches
  export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
  export QUILT_DIFF_ARGS='--no-timestamps'
  export LDFLAGS="${LDFLAGS} -Wl,--as-needed,-rpath,/usr/lib/${_pkgname}"
  export PYTHON="/usr/bin/python2"
  export DEBIAN_BUILD="comm-release"
  mv comm-esr10 "${DEBIAN_BUILD}"
  mv debian "${srcdir}/${DEBIAN_BUILD}"
  cd "${srcdir}/${DEBIAN_BUILD}"
  quilt push -av

  patch -Np1 -i "$srcdir/$_pkgname-2.0-lang.patch"
  patch -Np1 -i "$srcdir/gcc47.patch"
  patch -Np1 -i "$srcdir/clrf.patch"
  patch -Np1 -i "$srcdir/gnuzilla-addons.patch"

  cp "${srcdir}/mozconfig" .mozconfig
  make -j1 -f client.mk build MOZ_MAKE_FLAGS="${MAKEFLAGS}"
}

package() {
  cd "${srcdir}/${DEBIAN_BUILD}"

  make -j1 -f client.mk DESTDIR="${pkgdir}" install

  rm -rf "$pkgdir"/usr/lib/$_pkgname/{dictionaries,hyphenation,searchplugins}
  ln -sf /usr/share/hunspell "$pkgdir/usr/lib/$_pkgname/dictionaries"
  ln -sf /usr/share/hyphen "$pkgdir/usr/lib/$_pkgname/hyphenation"
  ln -sf /usr/lib/mozilla/searchplugins "$pkgdir/usr/lib/$_pkgname/searchplugins"

  install -m755 -d "$pkgdir/usr/share/applications"
  install -m755 -d "$pkgdir/usr/share/pixmaps"
  install -m644 moz-objdir/debian/branding/icons/gtk/iceape.png \
                "$pkgdir/usr/share/pixmaps/"
  install -m644 "$srcdir/$_pkgname.desktop" "$pkgdir/usr/share/applications/"

  rm -f "$pkgdir/usr/lib/pkgconfig/"$_pkgname-ns{s,pr}.pc
  rm -r "$pkgdir"/usr/{include,lib/$_pkgname-devel,share/idl}
}