# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
# Contributor (ConnochaetOS): Henry Jensen <hjensen@connochaetos.org>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: vando <facundo@esdebian.org>
# Contributor (Arch): Jakub Schmidtke <sjakub@gmail.com>
# Contributor: Figue <ffigue at gmail>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com>

_pgo=false

pkgname=icecat
_pkgver=45.5.1-gnu1
pkgver=${_pkgver//-/_}
pkgrel=2

pkgdesc="GNU IceCat, the standalone web browser based on Mozilla Firefox."
arch=(i686 x86_64 armv7h)
license=(MPL GPL LGPL)
depends=(alsa-lib dbus-glib desktop-file-utils ffmpeg gtk2 gtk3 hicolor-icon-theme hunspell icu=58.2 libevent libvpx=1.6.0 libxt mime-types mozilla-common nss sqlite startup-notification ttf-font)
makedepends=(diffutils gconf imake inetutils libpulse mesa mozilla-searchplugins python2 unzip yasm zip)
options=(!emptydirs !makeflags debug)
if $_pgo; then
  makedepends+=(xorg-server-xvfb)
  options+=(!ccache)
fi
optdepends=('networkmanager: Location detection via available WiFi networks'
            'upower: Battery API')
url="http://www.gnu.org/software/gnuzilla/"
install=$pkgname.install
source=(http://ftp.gnu.org/gnu/gnuzilla/${_pkgver%-*}/$pkgname-$_pkgver.tar.bz2{,.sig}
#mksource=(http://jenkins.trisquel.info/$pkgname/$pkgname-$_pkgver.tar.bz2)
#source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$_pkgver.tar.bz2{,.sig}
        mozconfig
        libre.patch
        gnu_headshadow.png
        $pkgname.desktop
        $pkgname-install-dir.patch
        firefox-gcc-6.0.patch
        gcc6-fix-compilation-for-IceCat.patch
        mozilla-1228540-1.patch
        vendor.js
        $pkgname-fixed-loading-icon.png
        no-libnotify.patch
        $pkgname-gtk3-20.patch
        disable-crypto-hardening-settings.patch
        disable-spoofSource-referer.patch
        no-neon.patch )
sha256sums=('8163e5bc53f69d9f9b0fc5e9f95fae33da8139ae0f902756751cadbaa27e6ee9'
            'SKIP'
            '89f375161a085ec37e88d5ceb9562dc33ed8ef03e225fefa819dfe3c6eb7290f'
            '583fe7b1897a7437854415c33cedefed1c987ca2ffea6b5826a99d4e7a71e05f'
            '93e3001ce152e1d142619e215a9ef07dd429943b99d21726c25da9ceb31e31cd'
            '52df9ffeb52166ed4abd9a132ee4a9017b9c4980f0725ba383610ccfb06d4745'
            '5bdab2de5520fb4d3dbc453d9f73d20e0e077bf652bc780fc17184ba6c718a47'
            '4d1e1ddabc9e975ed39f49e134559a29e01cd49439e358233f1ede43bf5a52bf'
            '329cf6753d29ae64a4336a8a76ee71f0d331a39132159401e4d11de65b708a07'
            'd1ccbaf0973615c57f7893355e5cd3a89efb4e91071d0ec376e429b50cf6ed19'
            '977aa49b940f1da049cefa2878a63ac6669a78e63e9d55bb11db7b8f8fb64c33'
            '68e3a5b47c6d175cc95b98b069a15205f027cab83af9e075818d38610feb6213'
            'e4ebdd14096d177d264a7993dbd5df46463605ff45f783732c26d30b9caa53a7'
            '2e355a477f1df792cd7f9d1e3a56030543e0cf2d09051dd293ba495a7edb54fd'
            '0166aa368420f0bf0aab064b2188e3d852b241efeeb27dee66df2bc15e84b83a'
            'c50043266e69f5844e6dce9ea7193af79587dcaa66806932d7867281a176f03e'
            '6d0c1c9ca28b20d206ce24ca84f4d4e3f5d062a2e9cb7445fcb6c2cfea959b4a')
validpgpkeys=(
              'A57369A8BABC2542B5A0368C3C76EED7D7E04784' # Ruben Rodriguez
)

prepare() {
  export GNU_BUILD="gnuzilla-release"

  mv $pkgname-${pkgver%_*} "$srcdir/$GNU_BUILD"
  cd "$srcdir/$GNU_BUILD"

  # Put gnu_headshadow.png in the source code
  install -m644 "$srcdir/gnu_headshadow.png" \
    browser/base/content/abouthome

  # Install to /usr/lib/$pkgname
  patch -Np1 -i "$srcdir/$pkgname-install-dir.patch"

  # https://bugzilla.mozilla.org/show_bug.cgi?id=1234158
  patch -Np1 -i "$srcdir/$pkgname-gtk3-20.patch"

  # Notifications with libnotify are broken
  # https://bugzilla.mozilla.org/show_bug.cgi?id=1236150
  patch -Np1 -i "$srcdir/no-libnotify.patch"

  # Compilation fix (FS#49243 and FS#49363), internet and Icedove package
  patch -Np1 -i $srcdir/gcc6-fix-compilation-for-IceCat.patch
  patch -Np1 -i $srcdir/firefox-gcc-6.0.patch

  # Update to harfbuzz (following Icedove in [libre])
  patch -Np1 -i $srcdir/mozilla-1228540-1.patch

  # Patch and remove anything that's left
  patch -Np1 -i "$srcdir/libre.patch"
  rm -v browser/base/content/abouthome/snippet*.png || true
  sed -i '\|abouthome/snippet|d
         ' browser/base/jar.mn

  # Load our build config, disable SafeSearch
  cp "$srcdir/mozconfig" .mozconfig

  mkdir "$srcdir/path"

  # WebRTC build tries to execute "python" and expects Python 2
  ln -s /usr/bin/python2 "$srcdir/path/python"

  # Configure script misdetects the preprocessor without an optimization level
  # https://bugs.archlinux.org/task/34644
  sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' configure

  # Fix tab loading icon (doesn't work with libpng 1.6)
  # https://bugzilla.mozilla.org/show_bug.cgi?id=841734
  cp "$srcdir/$pkgname-fixed-loading-icon.png" \
    browser/themes/linux/tabbrowser/loading.png

  # Load our searchplugins
  rm -rv browser/locales/en-US/searchplugins
  cp -av /usr/lib/mozilla/searchplugins browser/locales/en-US

  # Disable crypto hardening settings for now
  # https://lists.parabola.nu/pipermail/assist/2015-October/000534.html
  # https://labs.parabola.nu/issues/842
  patch -Np1 -i "$srcdir/disable-crypto-hardening-settings.patch"

  # Disable spoofSource referer since it breaks referer function used by some sites
  # https://labs.parabola.nu/issues/1073
  patch -Np1 -i "$srcdir/disable-spoofSource-referer.patch"

    # ARM-specific changes:
  if [[ "$CARCH" == arm* ]]; then
      sed -i '/ac_add_options --enable-rust/d' .mozconfig
      echo "ac_add_options --disable-ion" >> .mozconfig
      echo "ac_add_options --disable-elf-hack" >> .mozconfig
      echo "ac_add_options --disable-webrtc" >> .mozconfig

      # Disable gold linker, reduce memory consumption at link time
      sed -i '/ac_add_options --enable-gold/d' .mozconfig
      LDFLAGS+=" -Wl,--no-keep-memory -Wl,--reduce-memory-overheads"
      echo "ac_add_options --disable-tests" >> .mozconfig
      echo "ac_add_options --disable-debug" >> .mozconfig

      echo "ac_add_options --disable-neon" >> .mozconfig
      patch -Np0 -i ../no-neon.patch
  fi
}

build() {
  export GNU_BUILD="gnuzilla-release"

  cd "$srcdir/$GNU_BUILD"

  # _FORTIFY_SOURCE causes configure failures
  CPPFLAGS+=" -O2"

  # Hardening
  LDFLAGS+=" -Wl,-z,now"

  # GCC 6
  CFLAGS+=" -fno-delete-null-pointer-checks -fno-lifetime-dse -fno-schedule-insns2"
  CXXFLAGS+=" -fno-delete-null-pointer-checks -fno-lifetime-dse -fno-schedule-insns2"

  export PATH="$srcdir/path:$PATH"
  export PYTHON="/usr/bin/python2"

  if $_pgo; then
    # Do PGO
    xvfb-run -a -s "-extension GLX -screen 0 1280x1024x24" \
      make -f client.mk build MOZ_PGO=1
  else
    make -f client.mk build
  fi
}

package() {
  export GNU_BUILD="gnuzilla-release"

  cd "$srcdir/$GNU_BUILD"
  make -f client.mk DESTDIR="$pkgdir" INSTALL_SDK= install

  install -Dm644 ../vendor.js "$pkgdir/usr/lib/$pkgname/browser/defaults/preferences/vendor.js"

  brandingdir=browser/branding/official
  icondir="$pkgdir/usr/share/icons/hicolor"
  for i in 16 22 24 32 48 256; do
    install -Dm644 "$brandingdir/default$i.png" \
      "$icondir/${i}x${i}/apps/$pkgname.png"
  done
  install -Dm644 "$brandingdir/content/icon64.png" \
    "$icondir/64x64/apps/$pkgname.png"
  install -Dm644 "$brandingdir/mozicon128.png" \
    "$icondir/128x128/apps/$pkgname.png"
  install -Dm644 "$brandingdir/content/about-logo.png" \
    "$icondir/192x192/apps/$pkgname.png"
  install -Dm644 "$brandingdir/content/about-logo@2x.png" \
    "$icondir/384x384/apps/$pkgname.png"

  install -d "$pkgdir/usr/share/applications"
  install -m644 "$srcdir/$pkgname.desktop" \
    "$pkgdir/usr/share/applications"

  # Use system-provided dictionaries
  rm -rf "$pkgdir/usr/lib/$pkgname/"{dictionaries,hyphenation}
  ln -s /usr/share/hunspell "$pkgdir/usr/lib/$pkgname/dictionaries"
  ln -s /usr/share/hyphen   "$pkgdir/usr/lib/$pkgname/hyphenation"

  # Replace duplicate binary with symlink
  # https://bugzilla.mozilla.org/show_bug.cgi?id=658850
  ln -sf $pkgname "$pkgdir/usr/lib/$pkgname/$pkgname-bin"
}