# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=jedit
pkgver=5.3.0
pkgrel=4.parabola2
pkgdesc='Editor for programmers'
arch=('any')
url='http://jedit.org/'
license=('GPL')
depends=('java-runtime')
makedepends=('apache-ant' 'apache-ant-contrib' 'apache-ivy' 'beanshell2' 'docbook-xsl-saxon'
             'gendesk' 'java-hamcrest' 'jsr305' 'junit' 'xerces2-java')
optdepends=('java-environment: for java development'
            'noto-fonts: perfectly usable font')
options=('!emptydirs')
source=("http://sourceforge.net/projects/$pkgname/files/$pkgname/$pkgver/jedit${pkgver}source.tar.bz2"
        'jedit.sh'
        'jeditbg.sh'
        'jedit.props'
        'jedit-fix_build.patch')
sha256sums=('8d56d036be4dd45254748f063ade01293b862a615cdff6aed274ab58085f6304'
            'ae53cda453152dd7835d6428910171ca1383bb5e36a4b9b1164d98a940f6ed10'
            'a1dd1b688f08c5c967861fe80df13cac201afa6dcfcecc9a289b2c3bec7c8915'
            'dc5fe0050321d4f34bce556895fbc39cc6f7df194e14eb4f6ea53166a4d82347'
            '2676e043f9cd7e9e51322f5173ddf05f4ff2b68dc97d984b0b678c80478d4cee')

prepare() {
  gendesk -f -n --pkgname "$pkgname" --pkgdesc "$pkgdesc" --exec 'jeditbg %U' \
    --name 'jEdit' --genericname 'Editor'

  cd jEdit
  mkdir -p lib/{ant-contrib,compile,docbook,ivy,default-plugins,scripting,test}
  ln -sf /usr/share/java/ant-contrib.jar lib/ant-contrib/ant-contrib.jar
  ln -sf /usr/share/java/apache-ivy/ivy.jar lib/ivy/ivy.jar
  ln -sf /usr/share/java/bsh.jar lib/ant-contrib/bsh.jar
  ln -sf /usr/share/java/docbook-xsl-saxon.jar lib/docbook/docbook-xsl-saxon.jar
  ln -sf /usr/share/java/saxon.jar lib/docbook/saxon.jar
  ln -sf /usr/share/java/xercesImpl.jar lib/docbook/xercesImpl.jar
  ln -sf /usr/share/java/hamcrest-core.jar lib/test/hamcrest-core.jar
  ln -sf /usr/share/java/hamcrest-library.jar lib/test/hamcrest-library.jar
  ln -sf /usr/share/java/jsr305.jar lib/compile/jsr305.jar
  ln -sf /usr/share/java/junit.jar lib/test/junit.jar
  patch -Np1 -i "${srcdir}/jedit-fix_build.patch"
}

build() {
  cd jEdit
  ant build docs-html \
    -Divy.done=true
}

package() {
  cd jEdit

  # Install documentation
  install -d "$pkgdir/usr/share/java/$pkgname"
  cp -r build/doc "$pkgdir/usr/share/java/$pkgname"

  # Install jars
  install -D -m644 build/$pkgname.jar "$pkgdir/usr/share/java/$pkgname/$pkgname.jar"

  # Install keymaps
  cp -r build/keymaps "${pkgdir}/usr/share/java/${pkgname}"

  # Install macros
  cp -r build/macros "${pkgdir}/usr/share/java/${pkgname}"

  # Install modes
  cp -r build/modes "${pkgdir}/usr/share/java/${pkgname}"

  # Install properties
  cp -r build/properties "${pkgdir}/usr/share/java/${pkgname}"

  # Install startup
  cp -r build/startup "${pkgdir}/usr/share/java/${pkgname}"

  # Man pages
  install -Dm644 package-files/linux/$pkgname.1 "$pkgdir/usr/share/man/man1/$pkgname.1"

  # Launchers, properties and desktop shortcuts
  install -d "$pkgdir/usr/bin"
  install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
  install -Dm755 "$srcdir/${pkgname}bg.sh" "$pkgdir/usr/bin/${pkgname}bg"
  install -Dm644 "$srcdir/$pkgname.props" "$pkgdir/usr/share/$pkgname/default.props"
  install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 doc/$pkgname.png "$pkgdir/usr/share/pixmaps/$pkgname.png"
}