# $Id: PKGBUILD 158148 2012-05-03 13:20:53Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Maintainer (Parabola): Michał Masłowski <mtjm@mtjm.eu>
# Maintainer (Parabola): André Silva <andre.paulista@adinet.com.uy>

pkgbase=kdebase
_pkgname='kdebase-konqueror'
pkgname='kdebase-konqueror-libre'
pkgver=4.8.3
pkgrel=1.1
arch=('i686' 'x86_64' 'mips64el')
url="http://kde.org/applications/internet/konqueror/"
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdebase')
makedepends=('kdelibs' 'cmake' 'automoc4' 'tidyhtml')
source=("http://download.kde.org/stable/${pkgver}/src/kde-baseapps-${pkgver}.tar.xz"
    "konq-about-fsdg.diff")
sha1sums=('593053e7fdd50b32e6f9264edf2a69e499ddc0a6'
          'f41541371414dcbe5e76687835e648112b3ff364')
pkgdesc='KDE File Manager & Web Browser'
depends=('kdebase-dolphin' 'kdebase-keditbookmarks')
optdepends=('kwebkitpart: to enable webkit engine')
install='kdebase-konqueror.install'
conflicts=('kdebase-nsplugins' 'kdebase-konqueror')
replaces=('kdebase-nsplugins' 'kdebase-konqueror')
provides=("kdebase-konqueror=$pkgver")

build() {
    cd "${srcdir}"/kde-baseapps-${pkgver}

    # Don't recommend nonfree software or Google.
    patch -Np1 -i "${srcdir}/konq-about-fsdg.diff"

	cd ${srcdir}
	mkdir build
	cd build
	cmake ../kde-baseapps-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_SKIP_RPATH=ON \
		-DCMAKE_INSTALL_PREFIX=/usr
        for i in konqueror doc/konqueror nsplugins; do
            cd $srcdir/build/${i}
	    make
        done
}

package() {
        for i in konqueror doc/konqueror nsplugins; do
              cd $srcdir/build/${i}
              make DESTDIR=$pkgdir install
        done
}