# $Id: PKGBUILD 237798 2015-04-20 18:54:26Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgbase=kdebase-runtime
pkgname=kdebase-runtime
pkgver=15.04.0
pkgrel=4.parabola1
pkgdesc="Plugins and applications necessary for the running of KDE applications, without non-privacy search providers"
arch=('i686' 'x86_64' 'mips64el')
url='https://projects.kde.org/projects/kde/kde-runtime'
license=('GPL' 'LGPL')
makedepends=('kdelibs' 'libkactivities4' 'smbclient' 'libssh' 'libcanberra' 'libwebp'
	'pkg-config' 'cmake' 'automoc4' 'kdepimlibs' 'openslp' 'doxygen' 'networkmanager' 'boost')
source=("http://download.kde.org/stable/applications/${pkgver}/src/kde-runtime-${pkgver}.tar.xz"
        'duckduckgo_html.desktop'
        'duckduckgo_lite.desktop')
sha1sums=('5cbfec48ead85a1cd3dab675b98623dd4a831d91'
          'aa6f39f4b0ad3c110fd05cd6c41190afae9773dd'
          'ac3bac94a2c4b1444642524bc5fb539c4c5dcc5b')

prepare() {
  mkdir build

  cd kde-runtime-${pkgver}

  # Removing non-privacy search providers 
  rm -v kurifilter-plugins/ikws/searchproviders/{7digital,acronym,amazon{,_mp3},amg,backports,baidu,bing,blip,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,imdb,jamendo,jeeves,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop

  # Adding DuckDuckGo HTML
  cp -v "${srcdir}"/duckduckgo_html.desktop kurifilter-plugins/ikws/searchproviders

  # Adding DuckDuckGo Lite
  cp -v "${srcdir}"/duckduckgo_lite.desktop kurifilter-plugins/ikws/searchproviders
}

build() {
  cd build
  cmake ../kde-runtime-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_SKIP_RPATH=ON \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DWITH_QNtrack=OFF \
    -DSAMBA_INCLUDE_DIR=/usr/include/samba-4.0 \
    -DWITH_NepomukCore=OFF
  make
}

package_kdebase-runtime() {
  depends=('kdelibs' 'kactivities' 'libkactivities4' 'smbclient' 'libssh' 'libcanberra'
         'oxygen-icons' 'xorg-xauth' 'libwebp')
  optdepends=('kdepimlibs: for kwalletd, and is needed by DrKonqi to send crash reports to KDE.org' 'kdebase-runtime-doc: KDE4 documentation'
            'gdb: needed by DrKonqi to generate backtrace' 'khelpcenter: to display applications documentation')
  replaces=("${pkgname}-libre")
  conflicts=("${pkgname}-libre")
  provides=('notification-daemon')
  install=$pkgname.install

  cd build
  make DESTDIR="$pkgdir" install

  rm "${pkgdir}"/usr/share/icons/hicolor/index.theme

# Remove khelpcenter
  cd "$pkgdir"
  find -name '*khelpcenter*' | xargs rm -fr
  find -name 'khc*' | xargs rm -fr
  rm usr/share/applications/kde4/Help.desktop

# Remove docs
  rm -r "$pkgdir"/usr/share/{doc,man}

# Remove kdesu
  rm "$pkgdir"/usr/lib/kde4/libexec/kdesu*
}