# $Id: PKGBUILD 153517 2012-03-15 13:55:48Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor (Parabola): André Silva <andre.paulista@adinet.com.uy>

_pkgname=kdelibs
pkgname=kdelibs-libre
pkgver=4.8.1
pkgrel=2
pkgdesc="KDE Core Libraries"
arch=('i686' 'x86_64' 'mips64el')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
depends=('strigi' 'attica' 'libxss' 'xz' 'soprano' 'krb5' 'grantlee'
        'shared-desktop-ontologies' 'qca' 'libdbusmenu-qt' 'polkit-qt'
        'shared-mime-info' 'enchant' 'giflib' 'jasper' 'openexr' 'docbook-xsl'
        'upower' 'udisks' 'libxcursor' 'phonon' 'qtwebkit')
makedepends=('cmake' 'automoc4' 'avahi' 'libgl' 'hspell')
provides=("kdelibs=$pkgver")
replaces=('kdelibs-experimental' 'kdelibs')
conflicts=('kdelibs')
install=${_pkgname}.install
source=("http://download.kde.org/stable/${pkgver}/src/${_pkgname}-${pkgver}.tar.bz2"
        'kde-applications-menu.patch'
        'fix-kmail-crash.patch'
        'use-pythondontwritebytecode.patch'
        'khtml-fsdg.diff')
sha1sums=('ec393b096003f1dd57c5e2987381b086ba1b363e'
          '86ee8c8660f19de8141ac99cd6943964d97a1ed7'
          '081b0663480568359120b573d26abb91e1a348c0'
          'a1e35760d5b4e29471ad357c963a343c67200f32'
          'a1502a964081ad583a00cf90c56e74bf60121830')

build() {
       cd "${srcdir}"/${_pkgname}-${pkgver}

       # avoid file conflict with gnome-menus
       patch -p1 -i "${srcdir}"/kde-applications-menu.patch

       # Upstream (FS#28907)
       patch -p1 -i "${srcdir}"/fix-kmail-crash.patch

       # Set PYTHONDONTWRITEBYTECODE (KDEBUG#276151)
       patch -p0 -i "${srcdir}"/use-pythondontwritebytecode.patch

       # Don't ask the user to download a plugin, it's probably nonfree.
       patch -p1 -i "${srcdir}"/khtml-fsdg.diff

       cd "${srcdir}"
       mkdir build
       cd build
       cmake ../${_pkgname}-${pkgver} \
               -DCMAKE_BUILD_TYPE=Release \
               -DCMAKE_SKIP_RPATH=ON \
               -DKDE_DISTRIBUTION_TEXT='Parabola GNU/Linux-libre' \
               -DCMAKE_INSTALL_PREFIX=/usr \
               -DSYSCONF_INSTALL_DIR=/etc \
               -DHTML_INSTALL_DIR=/usr/share/doc/kde/html \
               -DKDE_DEFAULT_HOME='.kde4' \
               -DWITH_FAM=OFF
       make
}

package() {
       cd "${srcdir}"/build
       make DESTDIR="${pkgdir}" install

       # cert bundle seems to be hardcoded
       # link it to the one from ca-certificates
       rm -f "${pkgdir}"/usr/share/apps/kssl/ca-bundle.crt
       ln -sf /etc/ssl/certs/ca-certificates.crt "${pkgdir}"/usr/share/apps/kssl/ca-bundle.crt
}