# $Id: PKGBUILD 217314 2014-07-18 11:45:55Z svenstaro $
# Maintainer (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=kdenetwork-kopete
pkgname=kdenetwork-kopete-libre
pkgver=4.14.0
pkgrel=1
pkgdesc='Instant Messenger, without nonfree Skype support'
url='http://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdenetwork')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
depends=('kdebase-runtime' 'kdepimlibs' 'qca-ossl' 'libotr' 'libidn'
         'qimageblitz' 'libgadu' 'mediastreamer' 'jsoncpp')
makedepends=('cmake' 'automoc4' 'boost' 'kdepim-libkdepim')
install=${_pkgname}.install
source=("http://download.kde.org/stable/${pkgver}/src/kopete-${pkgver}.tar.xz")
sha1sums=('bd247af3b25650bedcdb983fc285469dcacea964')

prepare() {
  cd kopete-${pkgver}
  # Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
  rm -rv protocols/skype
  sed 's/, Skype//' -i doc/index.docbook
  cd ..
  mkdir build
}

build() {
  cd build
  cmake ../kopete-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DWITH_Libmsn=OFF \
    -DWITH_skype=OFF
  make
}

package() {
  cd build
  make DESTDIR=$pkgdir install
}