# $Id: PKGBUILD 213016 2014-05-17 10:20:26Z ronald $
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=digikam
_pkgname=kipi-plugins
pkgname=kipi-plugins-libre
pkgver=4.0.0
pkgrel=1
pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam, without nonfree jAlbum and SimpleViewer support"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.digikam.org/"
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
makedepends=('kdepimlibs' 'libkexiv2' 'libkdcraw' 'libkipi' 'libksane' 'liblqr'
             'kdeedu-marble' 'opencv' 'boost' 'libgpod' 'qjson' 'hugin' 'libgphoto2'
             'cmake' 'automoc4' 'doxygen' 'lensfun' 'qt-gstreamer' 'imagemagick' 'eigen')
depends=('kdebase-runtime' 'kdepimlibs' 'libkdcraw' 'libkipi' 'libksane' 'libkexiv2')
optdepends=('libkgeomap: Geolocalize tool'
            'libmediawiki: MediaWiki Export plugin'
            'libkvkontakte: VKontakte.ru Exporter plugin'
            'libgpod: iPodExport plugin'
            'opencv: Remove Red Eyes plugin'
            'imagemagick: Video SlideShow plugin'
            'qt-gstreamer: Video SlideShow plugin')
options=('staticlibs')
install=kipi-plugins.install
source=("http://download.kde.org/stable/${pkgbase}/${pkgbase}-${pkgver}.tar.bz2")
sha1sums=('23fd1e31e1f0518265c3165e620beb15cef4d41e')

prepare() {
  cd ${srcdir}/${pkgbase}-${pkgver}
  sed -i '\|flashexport|d
          \|jalbumexport|d
         ' extra/kipi-plugins/CMakeLists.txt
  cd ..
  mkdir build
}

build() {
  cd build
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DBUILD_tests=OFF \
    -DDIGIKAMSC_USE_PRIVATE_KDEGRAPHICS=OFF
  make
}

package() {
  cd build/extra/kipi-plugins
  make DESTDIR="${pkgdir}" install

  cd ../../../build/po
  make DESTDIR="${pkgdir}" install
  # Put these in the relevant splitted packages
  rm "${pkgdir}"/usr/share/locale/*/LC_MESSAGES/libkgeomap.mo
  rm "${pkgdir}"/usr/share/locale/*/LC_MESSAGES/digikam.mo
  # Fix conflicts with kde-l10n-* (FS#33762)
  rm "${pkgdir}"/usr/share/locale/*/LC_MESSAGES/libkipi.mo  
}