# $Id: PKGBUILD 83837 2013-02-05 15:58:20Z spupykin $
# Maintainer: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
# Contributor: solsTiCe d'Hiver <solstice.dhiver@gmail.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=lesspipe
pkgname=lesspipe-libre
pkgver=1.82
pkgrel=1
pkgdesc='an input filter for the pager less, with libarchive support'
depends=('less')
arch=('any')
license=('GPL')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
optdepends=('perl'
	    'rpmextract: support for rpm files'
	    'fastjar: support for jar files'
	    'unzip: support for zip files'
	    'libarchive: support for rar files'
	    'p7zip: support for 7za files'
	    'cabextract: support for cab files'
	    'cdrkit: support for iso files'
	    'html2text: support for html files'
	    'antiword: support for word file'
	    'unrtf: support for rtf file'
	    'imagemagick: support for some image file')
url="http://www-zeuthen.desy.de/~friebel/unix/lesspipe.html"
source=(http://downloads.sourceforge.net/project/lesspipe/lesspipe/$pkgver/lesspipe-$pkgver.tar.gz
	lesspipe.sh
	libarchive.patch)
md5sums=('dd6f7bc9b9f9afaf04c9aa0cdbe9fe56'
         '675b56f560c600f43108adfd98222251'
         'ec452ea980d5c1e254e9775fd424c18c')

prepare() {
  cd $srcdir/$_pkgname-$pkgver
  patch -Np1 -i ../libarchive.patch
}

build() {
  cd $srcdir/$_pkgname-$pkgver
  ./configure --prefix=/usr --yes
  make
}

package() {
  cd $srcdir/$_pkgname-$pkgver
  mkdir -p $pkgdir/usr/share/man/man1
  make install PREFIX=$pkgdir/usr
  install -D $srcdir/lesspipe.sh $pkgdir/etc/profile.d/lesspipe.sh
}