# Maintainer: Joshua Haase <hahj87@gmail.com
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>

pkgbase=libretools
pkgname=(libretools libretools-mips64el)
pkgver=20130117
pkgdesc="Programs for Parabola development"
url="https://projects.parabolagnulinux.org/libretools.git/"
license=('GPL3+' 'GPL2')

pkgrel=3
arch=('any')
groups=(base-devel)
depends=(openssh rsync git wget tokyocabinet)
conflicts=(chroottools)
source=(https://projects.parabolagnulinux.org/$pkgbase.git/snapshot/$pkgbase-$pkgver.tar)

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  make
}

package_libretools() {
  backup=(etc/libretools.conf etc/libretools.d/chroot.conf)
  install=libretools.install

  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools DESTDIR="$pkgdir"
  install -Dm755 rePKGBUILD.proto ${pkgdir}/usr/share/pacman/rePKGBUILD.proto
}

package_libretools-mips64el() {
  pkgdesc="Scripts for Parabola development (for mips64el architecture)"
  backup=('etc/libretools.d/mips64el.conf')

  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools-mips64el DESTDIR="$pkgdir"
}

md5sums=('77dcfb2fbf5b8a9894a13c5e6151b693')