# $Id: PKGBUILD 268568 2016-05-25 20:34:14Z arojas $
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: bitlord

pkgname=liferea
pkgver=1.10.19
pkgrel=1.parabola1
pkgdesc="A desktop news aggregator for online news feeds and weblogs, without nonfree suggestions"
arch=('i686' 'x86_64' 'armv7h')
url="http://liferea.sourceforge.net/"
replaces=('liferea-libre')
conflicts=('liferea-libre')
license=('GPL')
depends=('webkitgtk' 'libnotify' 'json-glib' 'libpeas' 'python2-gobject' 
         'desktop-file-utils')
makedepends=('intltool' 'gobject-introspection')
optdepends=('gnome-keyring: for keyring plugin support'
            'libgnome-keyring: for keyring plugin support'
	    'gst-plugins-base: for media player plugin support'
	    'gst-plugins-good: for media player plugin support'
	    'gst-plugins-bad: for media player plugin support')
options=('!emptydirs')
source=(https://github.com/lwindolf/liferea/releases/download/v${pkgver}/liferea-${pkgver}.tar.bz2
        remove-non-free-suggestions.patch)
sha1sums=('5afed65c2a91464ade8007d14e0c9d2fe54c90f6'
          'e787f9209415ed2574e54b020cf449268ece3583')

build() {
  cd liferea-${pkgver}
  # remove nonfree suggestions
  patch -p1 -i "$srcdir/remove-non-free-suggestions.patch"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --disable-schemas-compile
  make
}

package() {
  cd liferea-${pkgver}
  make DESTDIR="${pkgdir}" install
}