# Maintainer: Márcio Silva <coadde@parabola.nu>
# Contributor: André Silva <emulatorman@parabola.nu>

pkgbase=mesa
_pkgname=libcl
pkgname=$pkgbase-$_pkgname
pkgver=10.6.6
pkgrel=1
pkgdesc='Mesa 3-D OpenCL library and ICD loader'
arch=('i686' 'x86_64')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("$pkgbase" 'libclc' 'clang')


makedepends=('python2-mako' 'dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2' 'llvm')
provides=("$_pkgname" 'opencl-icd-loader')
conflicts=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx' 'ocl-icd')
replaces=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx')
source=(ftp://ftp.freedesktop.org/pub/$pkgbase/$pkgver/$pkgbase-$pkgver.tar.xz{,.sig}
        0001-i965-Remove-early-release-of-DRI2-miptree.patch)
sha512sums=('a251dc258ccf2fbeccbff3447a23c0f417722244322c8887fe4a50b0013d3da3705ffbfe412b61717d2c3370cb6a88bec51b91e1b77a5b987d6fbf0fdbfe4a5e'
            'SKIP'
            '86bfab88131440d1e5aefd157f12d8927c1a71af4f29b43c607bd2c37ee87f8164c92dc4309fade3c667f7d5907f99d0aa79b5fee1b8ff0eafe5f6d869bbed99')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>

prepare() {
  cd $srcdir/$pkgbase-$pkgver

  # Should fix FS#45750, tested by heftig - Not merged upstream
  patch -Np1 -i ../0001-i965-Remove-early-release-of-DRI2-miptree.patch
}

build() {
  cd $srcdir/$pkgbase-$pkgver

  #autoreconf -vfi # our automake is far too new for their build system :)

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --with-gallium-drivers=r300,r600,radeonsi,nouveau,svga,swrast \
    --with-egl-platforms=x11,drm,wayland \
    --enable-llvm-shared-libs \
    --enable-egl \
    --enable-gallium-llvm \
    --enable-opencl \
    --with-clang-libdir=/usr/lib
  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=$srcdir/fakeinstall install
}

package() {
  cd $srcdir/$pkgbase-$pkgver

  install -vm755 -d $pkgdir/usr/lib/
  mv -v $srcdir/fakeinstall/usr/lib/libOpenCL* $pkgdir/usr/lib/

  install -vm755 -d $pkgdir/usr/lib/gallium-pipe
  mv -v $srcdir/fakeinstall/usr/lib/gallium-pipe/pipe_{nouveau,r300,swrast,vmwgfx}.so $pkgdir/usr/lib/gallium-pipe/

  install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: