# $Id: PKGBUILD 198354 2013-10-30 14:21:29Z allan $
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=openexr
pkgname=openexr-libre
pkgver=2.0.1
pkgrel=2
pkgdesc="An high dynamic-range image file format library, without embedded nonfree fonts in the documentation"
url="http://www.openexr.com/"
arch=('i686' 'x86_64' 'mips64el')
license=('BSD')
depends=('zlib' 'ilmbase')
makedepends=('libcups' 'libxinerama')
[ "$CARCH" != "mips64el" ] && makedepends+=('libreoffice-writer' 'jre7-openjdk-headless')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
mksource=("http://download.savannah.nongnu.org/releases/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
          "https://repo.parabolagnulinux.org/other/${pkgname}/MultiViewOpenEXR.odt"
          "https://repo.parabolagnulinux.org/other/${pkgname}/OpenEXRFileLayout.odt"
          "https://repo.parabolagnulinux.org/other/${pkgname}/ReadingAndWritingImageFiles.odt"
          "https://repo.parabolagnulinux.org/other/${pkgname}/TechnicalIntroduction.odt")
source=("https://repo.parabolagnulinux.org/other/${pkgname}/${pkgname}-${pkgver}.tar.gz")
noextract=(MultiViewOpenEXR.odt OpenEXRFileLayout.odt ReadingAndWritingImageFiles.odt TechnicalIntroduction.odt)

mksource() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  # remove documentation with embedded nonfree fonts
  rm -rv "doc/"{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.pdf

  # add source documentation with free fonts
  install -m644 -v "${srcdir}/"{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt doc

  # convert documentation from odt to pdf format and clean source code
  if [ "$CARCH" != "mips64el" ]; then
    cd doc
    libreoffice --headless --invisible --convert-to pdf {MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt
    rm -rv "${srcdir}/"{Configurations2,META-INF,ObjBFFFDCA{1,3,4,5,7},Object\ 1,ObjectReplacements,Pictures,Thumbnails}
  fi
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"

  install -m644 "doc/"{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt "${pkgdir}/usr/share/doc/OpenEXR-${pkgver}"
}
mkmd5sums=('4387e6050d2faa65dd5215618ff2ddce'
           '69f117d3c91827e5de47f1e00137a4cc'
           '4d5ffa31f9af63bd5c621c6cbac6c673'
           'de099240193d8a51086dfae914fff3cf'
           'ece8bf90d438b89c6bd9fe4a89cc318a')
md5sums=('13e8ec945aa651a7a7f6aad133941866')