# $Id: PKGBUILD 212797 2014-05-15 10:44:29Z tpowa $
# Maintainer (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=openexr
_pkgname=$pkgname-libre
pkgver=2.1.0
pkgrel=1.parabola1
pkgdesc="An high dynamic-range image file format library, without embedded nonfree fonts in the documentation"
url="http://www.$pkgname.com/"
arch=('i686' 'x86_64' 'mips64el')
license=('BSD')
depends=('zlib' 'ilmbase')
makedepends=('jre7-openjdk-headless' 'libcups' 'libreoffice-writer' 'libxinerama')
replaces=("$_pkgname")
conflicts=("$_pkgname")
mksource=("http://download.savannah.nongnu.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.gz"
          "https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/InterpretingDeepPixels.docx"
          "https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/MultiViewOpenEXR.odt"
          "https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/OpenEXRFileLayout.odt"
          "https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/ReadingAndWritingImageFiles.odt"
          "https://github.com/${pkgname}/${pkgname}/raw/master/OpenEXR/doc/TechnicalIntroduction.odt")
source=("https://repo.parabolagnulinux.org/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
noextract=(InterpretingDeepPixels.docx MultiViewOpenEXR.odt OpenEXRFileLayout.odt ReadingAndWritingImageFiles.odt TechnicalIntroduction.odt)

mksource() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # remove documentation with embedded nonfree fonts
  rm -rv "doc/"{InterpretingDeepPixels,MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction,TheoryDeepPixels}.pdf

  # add source documentation
  install -m644 -v "${srcdir}/"{InterpretingDeepPixels.docx,{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt} doc

  # convert source documentation to pdf format and clean source code
  if [ "$CARCH" != "mips64el" ]; then
    cd doc
    libreoffice --headless --invisible --convert-to pdf {InterpretingDeepPixels.docx,{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt}
    rm -rv "${srcdir}/"{_rels,Configurations2,customXml,docProps,META-INF,ObjBFFFDCA{1,3,4,5,7},Object\ 1,ObjectReplacements,Pictures,Thumbnails,word}
  fi
}

prepare() {
  # remove TheoryDeepPixels.pdf reference
  sed -i '\|TheoryDeepPixels[.]pdf|d
          \|InterpretingDeepPixels[.]pdf| s| [\]||
         ' "${srcdir}/${pkgname}-${pkgver}/doc/Makefile."{am,in}
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -m644 "doc/"{InterpretingDeepPixels.docx,{MultiViewOpenEXR,OpenEXRFileLayout,ReadingAndWritingImageFiles,TechnicalIntroduction}.odt} "${pkgdir}/usr/share/doc/OpenEXR-${pkgver}"
}
mkmd5sums=('33735d37d2ee01c6d8fbd0df94fb8b43'
           'a59a8516d9dbb76755cb258d18cf4e72'
           '0b0b41269d6a3ee1a7090067cc89895f'
           '6889a150ab9f2f35fbc9835373dd3c34'
           'ef6912faf2ab7516678bd0fa56b832f8'
           '232a6be90fd36ce49e213492a60d335d')
md5sums=('97613563c17dc3a1aa3359e05b7b37da')