# Maintainer (Arch): Daniel Micay <danielmicay@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Maintainer: Luke .R <g4jc@openmailbox.org>

_pkgname=paxd
pkgname=paxd-libre
pkgver=1.12
pkgrel=1
pkgdesc='PaX exception daemon (a libre fork of paxd)'
arch=(i686 x86_64 armv7h)
url='https://github.com/g4jc/paxd-libre/'
license=(MIT)
replaces=($_pkgname linux-pax-flags)
conflicts=($_pkgname linux-pax-flags)
provides=($_pkgname linux-pax-flags)
depends=(glib2)
source=($pkgname-$pkgver.tar.gz::https://github.com/g4jc/paxd-libre/archive/$pkgver.tar.gz
	10-enable-pax.conf)
sha1sums=('a3153bb7628fa59df869c527b160b066974ccdc8'
          '8ee73dd288bc32438078e032dfc50a2f8ea6a5f2')
backup=(etc/paxd-libre.conf)

build() {
  cd $pkgname-$pkgver
  make CC=gcc
}

package() {
  cd $pkgname-$pkgver
  mkdir -p "$pkgdir/usr/lib/systemd/system/sysinit.target.wants"
  make PREFIX=/usr DESTDIR="$pkgdir" install
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 ../10-enable-pax.conf "$pkgdir/usr/lib/sysctl.d/10-enable-pax.conf"
}