# Maintainer: Márcio Silva <coadde@parabola.nu>
# based of readline

_pkgname=readline
pkgname=readline-static
_basever=6.3
_patchlevel=008
pkgver=$_basever.$_patchlevel
pkgrel=3
pkgdesc='GNU readline library (static libraries only)'
arch=('i686' 'x86_64' 'armv7h')
url='http://tiswww.case.edu/php/chet/readline/rltop.html'
license=('GPL')
depends=('ncurses-static' 'readline')
options=('!emptydirs' 'staticlibs')
source=(http://ftp.gnu.org/gnu/readline/readline-$_basever.tar.gz{,.sig})
validpgpkeys=('7C0135FB088AAF6C66C650B9BB5869F064EA74AB') # Chet Ramey

if [ $_patchlevel -gt 0 ]; then
    for (( _p=1; _p <= $((10#${_patchlevel})); _p++ )); do
        source=(${source[@]} http://ftp.gnu.org/gnu/readline/readline-$_basever-patches/readline${_basever//.}-$(printf "%03d" $_p){,.sig})
    done
fi

prepare() {
  cd $_pkgname-$_basever
  for (( _p=1; _p <= $((10#${_patchlevel})); _p++ )); do
    msg "applying patch readline${_basever//.}-$(printf "%03d" $_p)"
    patch -p0 -i ../readline${_basever//.}-$(printf "%03d" $_p)
  done

  # remove RPATH from shared objects (FS#14366)
  sed -i 's|-Wl,-rpath,$(libdir) ||g' support/shobj-conf
}

build() {
  cd $_pkgname-$_basever

  # build with -fPIC for x86_64 (FS#15634)
  [[ $CARCH == "x86_64" ]] && CFLAGS="$CFLAGS -fPIC"

  ./configure --prefix=/usr
  make SHLIB_LIBS=-lncurses
}

package() {
  make -C $_pkgname-$_basever DESTDIR="$pkgdir" install

  # remove conflicting files
  rm -vr ${pkgdir}/usr/{include,share}
  rm -v ${pkgdir}/usr/lib/lib*.so*
}

md5sums=('33c8fb279e981274f485fd91da77e94a'
         'SKIP'
         '4343f5ea9b0f42447f102fb61576b398'
         'SKIP'
         '700295212f7e2978577feaee584afddb'
         'SKIP'
         'af4963862f5156fbf9111c2c6fa86ed7'
         'SKIP'
         '11f9def89803a5052db3ba72394ce14f'
         'SKIP'
         '93721c31cd225393f80cb3aadb165544'
         'SKIP'
         '71dc6ecce66d1489b96595f55d142a52'
         'SKIP'
         '062a08ed60679d3c4878710b3d595b65'
         'SKIP'
         'ee1c04072154826870848d8b218d7b04'
         'SKIP')