# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

pkgname=stuntrally-data-libre
_pkgname=stuntrally-data
pkgver=2.0
pkgrel=1
pkgdesc="Stunt Rally game with track editor, based on VDrift (data files), without nonfree data files"
arch=('any')
license=('GPL3' 'custom')
url="http://code.google.com/p/vdrift-ogre"
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
makedepends=('cmake' 'boost' 'libvorbis' 'mygui' 'sdl' 'enet' 'hicolor-icon-theme' 'libxcursor')
source=(StuntRally-$pkgver-sources.tar.xz::http://sourceforge.net/projects/stuntrally/files/$pkgver/StuntRally-$pkgver-sources.tar.xz/download
        libre.patch )
md5sums=('22eb331c4401a0ed03e7a9e916fdb60c'
         'e96df3ba70d6fd0949bb92f4dd609497')
prepare() {
  # patch some data files and remove nonfree data files
  cd $srcdir/StuntRally-$pkgver-sources

  patch -Np1 -i $srcdir/libre.patch

  rm -rv "data/"{grass/grassJungle.png,sounds/{0{1,2,3,4,5,6,7,8,9},1{0,1,2},boost,dirt{1,2},mud{1,_cont},scrap,screech,terrain{1,2,3,4,5},water{1,2,3,_cont}}.wav,terrain,trees2,cars/{3S,CT,M3,NS,TC6,XM},tracks/{detroit,ruudskogen,virginia,weekend}}
}

build() {
  # build the sources
  cd $srcdir/StuntRally-$pkgver-sources

  mkdir build && cd build

  cmake .. \
      -DCMAKE_INSTALL_PREFIX="/usr" \
      -DSHARE_INSTALL="share/stuntrally"
  make
}

package() {
  #install the sources
  cd $srcdir/StuntRally-$pkgver-sources/build
  make DESTDIR="$pkgdir" install

  # clean up
  rm -rf "$pkgdir/usr/share/stuntrally/tracks/build"
  rm -rf "$pkgdir/usr/share/icons"
  rm -rf "$pkgdir/usr/share/applications"
  rm -rf "$pkgdir/usr/bin"
}