# U-Boot: ChiliBoard
# Maintainer (Arch): Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: André Silva <emulatorman@parabola.nu>

buildarch=4

_pkgname=linux-libre
pkgname=uboot-chiliboard-${_pkgname}
pkgver=2014.07
pkgrel=1.2
pkgdesc="U-Boot for ChiliBoard (built for the linux-libre kernel package)"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
makedepends=('bc')
depends=('linux-libre')
replaces=('uboot-chiliboard')
license=('GPL')
install=${pkgname}.install
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-Add-linux-compiler-gcc5.h-to-fix-builds-with-gcc5.patch'
        '0002-ARM-asm-io.h-use-static-inline.patch'
        '0003-common-main.c-make-show_boot_progress-__weak.patch'
        '0004-common-board_f-cosmetic-use-__weak-for-leds.patch'
        '0005-chiliboard-support.patch'
        '0006-parabola-arm-modifications.patch'
        'uEnv.txt')
md5sums=('36d4bad687edcafa396fee607e505d4e'
         'e070e8b5cf8628b6440dfc9dbd87cb65'
         '318310de19110167fe15ceac3ae32f7d'
         '1792346431786e1442c4059cd3f288ed'
         '2a32a77f123391c02935754ced2743c2'
         '5fb23405ca6fb54072ae6a9cfa4cb625'
         '52fcdef066e39169cefed9c9d8715f4a'
         '0afad1f6f3f8609db6e1f5bb322b2a1a')

prepare() {
  cd u-boot-${pkgver}
  patch -Np1 -i ../0001-Add-linux-compiler-gcc5.h-to-fix-builds-with-gcc5.patch
  patch -Np1 -i ../0002-ARM-asm-io.h-use-static-inline.patch
  patch -Np1 -i ../0003-common-main.c-make-show_boot_progress-__weak.patch
  patch -Np1 -i ../0004-common-board_f-cosmetic-use-__weak-for-leds.patch
  patch -Np1 -i ../0005-chiliboard-support.patch
  patch -Np1 -i ../0006-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}

  unset CFLAGS CXXFLAGS LDFLAGS

  make distclean 
  make chiliboard_config
  make
}

package() {
  cd u-boot-${pkgver}
  mkdir -p "${pkgdir}/boot/${pkgname}"
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}/boot/${pkgname}"
}