# U-Boot: PandaBoard and PandaBoard ES
# Maintainer (Arch): Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: André Silva <emulatorman@parabola.nu>

buildarch=4

_pkgname=linux-libre
pkgname=uboot-pandaboard-${_pkgname}
pkgver=2015.04
pkgrel=1.1
pkgdesc="U-Boot for PandaBoard and PandaBoard ES (built for the linux-libre kernel package)"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
makedepends=('bc')
replaces=('uboot-pandaboard')
license=('GPL')
install=${pkgname}.install
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        'uEnv.txt')
md5sums=('570bdc2c47270c2a98ca60ff6c5c74cd'
         'ed3771f68122d6846dc9d906df6a1e6d'
         '86004660f2912861a040e335c9c0e85b')

prepare() {
  cd u-boot-${pkgver}

  patch -Np1 -i ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}

  unset LDFLAGS

  make distclean 
  make omap4_panda_config
  make
}

package() {
  cd u-boot-${pkgver}

  mkdir -p "${pkgdir}/boot/${pkgname}"
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}/boot/${pkgname}"
}