# U-Boot: Wandboard
# Maintainer (Arch): Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: André Silva <emulatorman@parabola.nu>

buildarch=4

_pkgbase=linux-libre
pkgbase=uboot-wandboard-${_pkgbase}
pkgname=("uboot-wandboard-solo-${_pkgbase}" "uboot-wandboard-dual-${_pkgbase}" "uboot-wandboard-quad-${_pkgbase}")
pkgver=2015.04
pkgrel=1
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
makedepends=('bc')
depends=('linux-libre')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch')
md5sums=('570bdc2c47270c2a98ca60ff6c5c74cd'
         '9fdd58f6cb2431ceef6cbf29ce89d1d4')

prepare() {
  cd u-boot-${pkgver}
  patch -Np1 -i ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}
  
  unset LDFLAGS
  
  mkdir bins
  for i in solo dl quad; do
    make distclean
    make wandboard_${i}_config
    make
    mv u-boot.imx bins/u-boot-${i}.imx
  done
}

package_uboot-wandboard-solo-linux-libre() {
  pkgdesc="U-Boot for Wandboard Solo (built for the linux-libre kernel package)"
  replaces=('uboot-wandboard-solo')
  install=${pkgname}.install

  mkdir -p "${pkgdir}/boot/${pkgname}"
  cp u-boot-${pkgver}/bins/u-boot-solo.imx "${pkgdir}/boot/${pkgname}"/u-boot.imx
}

package_uboot-wandboard-dual-linux-libre() {
  pkgdesc="U-Boot for Wandboard Dual (built for the linux-libre kernel package)"
  replaces=('uboot-wandboard-dual')
  install=${pkgname}.install

  mkdir -p "${pkgdir}/boot/${pkgname}"
  cp u-boot-${pkgver}/bins/u-boot-dl.imx "${pkgdir}/boot/${pkgname}"/u-boot.imx
}

package_uboot-wandboard-quad-linux-libre() {
  pkgdesc="U-Boot for Wandboard Quad (built for the linux-libre kernel package)"
  replaces=('uboot-wandboard-quad')
  install=${pkgname}.install

  mkdir -p "${pkgdir}/boot/${pkgname}"
  cp u-boot-${pkgver}/bins/u-boot-quad.imx "${pkgdir}/boot/${pkgname}"/u-boot.imx
}