# $Id: PKGBUILD 242411 2015-07-22 01:56:20Z eric $
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=xscreensaver
_pkgname=$pkgname-libre
pkgver=5.33
pkgrel=2.parabola1
pkgdesc="Screen saver and locker for the X Window System, without nonfree asm files"
arch=('i686' 'x86_64')
url="http://www.jwz.org/xscreensaver/"
license=('BSD')
depends=('libglade' 'libxmu' 'glu' 'xorg-appres' 'perl-libwww')
makedepends=('bc' 'intltool' 'libxpm' 'gdm')
optdepends=('gdm: for login manager support')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
backup=('etc/pam.d/xscreensaver')
mksource=(http://www.jwz.org/xscreensaver/${pkgname}-${pkgver}.tar.gz)
source=(https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz
        xscreensaver-add-electricsheep.diff
        xscreensaver-missingescape.patch
        LICENSE)
mksha1sums=('99f69ff0bef5e13ab0c84dcb1312605db485bafd')
sha1sums=('0fb0df0dc708a56287e0b25d62bfe9a01da945be'
          'e8dc57b6471fb3867ee099304ac6bf628351cb98'
          'ab2962f497e0b50a2ffe135baefdc155b0be1413'
          '3eedb8b91b13c29df9b1fe5cbb027e1470b802d2')

mksource() {
  cd ${pkgname}-${pkgver}

  # Deleting dmsc.asm file due which don't have source code supplied
  rm -v hacks/images/m6502/dmsc.asm
}

prepare() {
  cd ${pkgname}-${pkgver}
  patch -p0 -i "${srcdir}/xscreensaver-add-electricsheep.diff"
  patch -p1 -i "${srcdir}/xscreensaver-missingescape.patch"
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib --with-x-app-defaults=/usr/share/X11/app-defaults \
    --with-pam --with-login-manager --with-gtk --with-gl \
    --without-gle --with-pixbuf --with-jpeg
  make
}

package() {
  cd ${pkgname}-${pkgver}
  install -d "${pkgdir}/etc/pam.d"
  make install_prefix="${pkgdir}" install
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  chmod 755 "${pkgdir}/usr/bin/xscreensaver"
  echo "NotShowIn=KDE;GNOME;" >> "${pkgdir}/usr/share/applications/xscreensaver-properties.desktop"
}