# $Id: PKGBUILD 235995 2015-04-09 21:02:45Z andyrtr $
# Maintainer (Arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=claws-mail
pkgver=3.11.1
pkgrel=2.nonprism1
pkgdesc="A GTK+ based e-mail client, without libgdata support"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL3')
url="http://www.$pkgname.org"
depends=('gtk2' 'gnutls' 'startup-notification' 'enchant' 'gpgme' 'libetpan' 'compface'
         'libsm' 'dbus-glib' 'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('spamassassin' 'bogofilter' 'valgrind'
             # dependencies for plugins
             'libsoup' 'webkitgtk2' 'libnotify' 'libcanberra' 'poppler-glib' 'pygtk') 
             #'libchamplain' needed for geolocation plugin, disabled for now - most time it's not compatible with current gnome releases
optdepends=('python2:           needed for some tools and python plugin'
            'perl:              needed for some tools and perl plugin'
            'spamassassin:      adds support for spamfiltering'
            'bogofilter:        adds support for spamfiltering'
            'libnotify:         for notification plugin'
            'libcanberra:       for notification plugin'
            'dbus:              for notification plugin'
            'libxml2:           for gtkhtml2_viewer and rssyl plugins'
            'curl:              for gtkhtml2_viewer, vcalendar, rssyl and spamreport plugins'
            'libarchive:        for archive plugin and various other plugins'
            'libytnef:          for tnef_parse plugin'
            'webkitgtk2:        for the fancy webkit html plugin'
            'libsoup:           for the fancy webkit html plugin'
	        'poppler-glib:      for pdf viewer plugin'
	        'ghostscript:       for pdf viewer plugin')
replaces=("sylpheed-claws" "$pkgname-extra-plugins" "$pkgname-libre" "$pkgname-libre-nonprism" "$pkgname-nonprism")
conflicts=("$pkgname-extra-plugins" "$pkgname-libre" "$pkgname-libre-nonprism" "$pkgname-nonprism")
provides=('claws')
install=$pkgname.install
source=(http://downloads.sourceforge.net/sourceforge/claws-mail/$pkgname-$pkgver.tar.xz{,.asc}
        git_fixes.diff)
sha1sums=('b0c07906043f7a3ec726c7a96d6dcfc3c148b9cc'
          'SKIP'
          '0e1bd9d696d531040f7b15b5b6164fc44784fdfc')
validpgpkeys=('8B3B297A03468356692F8D592CD716D654D6BBD4') # Paul <paul@claws-mail.org>

prepare() {
  cd $pkgname-$pkgver
  # fix .desktop file creation
  patch -Np1 -i $srcdir/git_fixes.diff
  autoreconf -vfi
}

build() {
  cd $pkgname-$pkgver

  # fixes for python2
  export PYTHON="/usr/bin/python2"
  sed -i 's@^#!.*python.*@#!/usr/bin/python2@' tools/*.py
  sed -i 's:python -c:python2 -c:g' configure

  setarch $CARCH ./configure --prefix=/usr --disable-static \
    --enable-enchant \
    --enable-gnutls \
    --enable-ldap \
    --enable-crash-dialog \
    --enable-pgpmime-plugin \
    --enable-spamassassin-plugin \
    --enable-bogofilter-plugin \
    --enable-appdata \
    --disable-gdata-plugin
    #--help
  setarch $CARCH make
}

package() {
  cd $pkgname-$pkgver
  setarch $CARCH make DESTDIR=$pkgdir install

  # build and install extra tools
  cd tools
  setarch $CARCH make
   # all executables and .conf files ; only top directory
  find -maxdepth 1 -type f -and -perm /111 -or -name '*.conf' | while read i ; do
      install -D -m755 $i \
        $pkgdir/usr/lib/$pkgname/tools/$i
  done
}