# $Id: PKGBUILD 222758 2014-09-23 07:58:23Z jgc $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=eog-plugins
pkgver=3.14.0
pkgrel=1.nonprism1
pkgdesc="Plugins for Eye of Gnome, without libgdata support"
arch=('i686' 'x86_64' 'mips64el')
url="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins"
license=('GPL2')
depends=('eog' 'libchamplain')
makedepends=('intltool')
conflicts=(${pkgname}-nonprism)
replaces=(${pkgname}-nonprism)
install=eog-plugins.install
source=(http://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('761e604a5a50ccc503d600ac7a59487cca7ded773f9009a164dd87f1f90bb230')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
    --sysconfdir=/etc --localstatedir=/var

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: