# $Id: PKGBUILD 237184 2015-04-15 17:57:23Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=kdepim-runtime
pkgver=4.14.7
_kdeappver=15.04.0
pkgrel=1.nonprism1
pkgdesc='Extends the functionality of kdepim, without libkgapi and libkfbapi support'
arch=('i686' 'x86_64' 'mips64el')
url='https://projects.kde.org/projects/kde/kdepim-runtime'
license=('GPL' 'LGPL' 'FDL')
depends=('kdebase-runtime' 'libkolab' 'libaccounts-qt' 'libsignon-qt4')
makedepends=('cmake' 'automoc4' 'boost')
install="${pkgname}.install"
replaces=('kdepim-runtime-coherence' 'kdepim-runtime-nonprism')
conflicts=('kdepim-runtime-coherence' 'kdepim-runtime-nonprism')
source=("http://download.kde.org/stable/applications/${_kdeappver}/src/${pkgname}-${pkgver}.tar.xz")
sha1sums=('b5ceac3f2e3fc14b2f823afb22d12aa51798c833')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}