# $Id: PKGBUILD 195339 2016-11-11 10:34:45Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Joeny Ang <ang(dot)joeny(at)gmail(dot)com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=shotwell
epoch=1
pkgver=0.24.2
_basever=$(echo $pkgver | cut -f1-2 -d.)
pkgrel=1.nonprism1
pkgdesc="A digital photo organizer designed for the GNOME desktop environment, without support for unsafe and dangerous for privacy protocols"
arch=('i686' 'x86_64' 'armv7h')
url="http://yorba.org/shotwell/"
license=('LGPL2.1')
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=('libgee' 'webkit2gtk' 'libgexiv2' 'libraw' 'rest'
	 'desktop-file-utils' 'dconf' 'hicolor-icon-theme' 'json-glib'
	 'gst-plugins-base' 'libgphoto2' 'libgudev')
makedepends=('intltool' 'vala>=0.17.2' 'gnome-doc-utils' 'itstool')
source=("https://download.gnome.org/sources/shotwell/${_basever}/shotwell-$pkgver.tar.xz"
        'nonprism.patch')
md5sums=('4c4c6535be26abcb948d4c200a8516d0'
         'e79edee9bb1dadddd873945dc0f652ce')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i ../nonprism.patch

  cd po
  sed -i '\|set_background_slideshow_dialog.glade|d' $(grep -rIl set_background_slideshow_dialog.glade)
  for file in *.po; do
    intltool-update ${file%.*}
    msgattrib --no-obsolete -o $file $file
  done
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --libexec=/usr/lib \
	--disable-schemas-compile \
	--disable-desktop-update \
	--disable-icon-update \
        --disable-extra-plugins-install
  make -j1
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}