# Maintainer: Jorge Araya Navarro <elcorreo@deshackra.com>
# Maintainer (Arch): Benoit Favre <benoit.favre@gmail.com>
# Contributor (Arch): Alexander Rødseth <rodseth@gmail.com>
# Contributor: Kamil Biduś <kamil.bidus@gmail.com>

pkgname=aseprite
pkgver=1.1.5.6
pkgrel=3
pkgdesc='Create animated sprites and pixel art'
arch=('x86_64' 'i686')
url='http://www.aseprite.org/'
license=('GPL')
depends=('pixman' 'curl' 'giflib' 'zlib' 'libpng' 'libjpeg-turbo' 'tinyxml'
         'freetype2' 'libwebp' 'libxext')
makedepends=('cmake')
source=("http://repo.parabola.nu/other/pcr/aseprite-1.1.5.6-4-i686.src.tar.xz"
        aseprite.desktop)
sha256sums=('a3be7a09bdd670cac2fd15870eaa3b0b539eba486d89f6f2b6a4f9793ad77b6f'
            'c9e624b9fd095ebb3eec8220a58d4a9422f39d68477bafcc0047d773814ba0aa')

build() {
  cd "$pkgname"

  mkdir -p build && cd build 
  
  cmake -DUSE_SHARED_PIXMAN=ON \
        -DWITH_WEBP_SUPPORT=ON \
        -DUSE_SHARED_LIBWEBP=ON \
        -DUSE_SHARED_CURL=ON \
        -DUSE_SHARED_GIFLIB=ON \
        -DUSE_SHARED_JPEGLIB=ON \
        -DUSE_SHARED_ZLIB=ON \
        -DUSE_SHARED_LIBPNG=ON \
        -DUSE_SHARED_LIBLOADPNG=OFF \
        -DUSE_SHARED_TINYXML=ON \
        -DENABLE_UPDATER=OFF \
        -DUSE_SHARED_FREETYPE=ON \
        -DFREETYPE_INCLUDE_DIR=/usr/include/freetype2 \
        -Wno-dev \
        -DCMAKE_INSTALL_PREFIX:STRING=/usr ..
  make aseprite
}

package() {
  cd "$pkgname"/build

  make DESTDIR="$pkgdir/" install/fast
  install -Dm644 "$srcdir/$pkgname.desktop" \
          "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 "../data/icons/ase48.png" \
          "$pkgdir/usr/share/pixmaps/$pkgname.png"
}

# vim:set ts=2 sw=2 et: