# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

pkgname=ha-heartbeat
_pkgname=${pkgname:3}
pkgver=3.0.5
_pkgver=${pkgver::1}_${pkgver:2:1}
pkgrel=2
pkgdesc='Daemon that provides cluster infrastructure services to its clients'
arch=(
  i686
  x86_64
  mips64el
)
url=http://linux-ha.org/wiki/${_pkgname^}
license=GPL
makedepends=docbook-xsl
depends=(
  gnutls
  ha-glue
)
options=(
  '!emptydirs'
  '!libtool'
  strip
)
source=(
  http://hg.linux-ha.org/$_pkgname-STABLE_$_pkgver/archive/STABLE-$pkgver.tar.bz2
  $pkgname.service
)
sha512sums=(
  e38083b87c56a72eb8925ac42adeabb92618608e92218a63960ec0d0bca264f92a8e9c3ebfb0589cc4538da1a82b268b5cc9ee5a51ed33057c969e694e16b27d
  d14013b4ee133ed07e17fa6e09cae1f9f7bdbabaadfda9b9bb8ed25d4d5ff2f3d419f344195c6d5211da33293d5fe5ad64dbc8be6e1a02f7fa21563f54907a20
)

prepare() {
  cd $srcdir/${_pkgname^}-3-0-STABLE-$pkgver
  sed -i 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|' configure.in
  mv configure.{in,ac}
}

build() {
  cd $srcdir/${_pkgname^}-3-0-STABLE-$pkgver
  setarch $CARCH ./bootstrap
  setarch $CARCH ./configure --prefix=/usr\
    --enable-fatal-warnings=no\
    --enable-static=no\
    --libdir=/usr/lib\
    --sysconfdir=/etc
  setarch $CARCH make
}

package() {
  cd $srcdir/${_pkgname^}-3-0-STABLE-$pkgver
  setarch $CARCH make DESTDIR=$pkgdir install

  for py in `grep -r -l "\#\!\/usr\/bin\/python" $pkgdir`;do
    sed -i.bk 's:/usr/bin/python$:/usr/bin/python2:g' $py
  done
  for py in `grep -r -l "\#\!\/usr\/bin\/env python" $pkgdir`;do
    sed -i.bk 's:/usr/bin/env python$:/usr/bin/env python2:g' $py
  done
  #end python path correction

  install -d $pkgdir/usr/lib/systemd/system
  install -Dm644 $srcdir/$pkgname.service $pkgdir/usr/lib/systemd/system
}