# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

pkgname=ha-heartbeat
_pkgname=${pkgname:3}
pkgver=3.0.5
_pkgver=${pkgver::1}_${pkgver:2:1}
pkgrel=6
pkgdesc='Daemon that provides cluster infrastructure services to its clients'
arch=(
  i686
  x86_64
  mips64el
)
url=http://linux-ha.org/wiki/${_pkgname^}
license=(
  GPL2
  lGPL2.1
)
depends=(
  gnutls
  ha-glue
)
optdepends=(
  lynx
  net-tools
  openssh
  swig
  valgrind
  w3m
)
makedepends=(
  docbook-xsl
  libxslt
  lynx
  net-tools
  openssh
  swig
  valgrind
  w3m
)
options=!libtool
source=(
  http://hg.linux-ha.org/$_pkgname-STABLE_$_pkgver/archive/STABLE-$pkgver.tar.bz2
  $pkgname.service
)
sha512sums=(
  e38083b87c56a72eb8925ac42adeabb92618608e92218a63960ec0d0bca264f92a8e9c3ebfb0589cc4538da1a82b268b5cc9ee5a51ed33057c969e694e16b27d
  d14013b4ee133ed07e17fa6e09cae1f9f7bdbabaadfda9b9bb8ed25d4d5ff2f3d419f344195c6d5211da33293d5fe5ad64dbc8be6e1a02f7fa21563f54907a20
)

prepare() {
  cd $srcdir/${_pkgname^}-3-0-STABLE-$pkgver
  mv configure.{in,ac}
  sed -i 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|;
          s|AM_INIT_AUTOMAKE(heartbeat, $HAPKGVERSION)|AM_INIT_AUTOMAKE|;
         ' configure.ac
  sed -i "s|AC_INIT(GNUmakefile)|AC_INIT(heartbeat, $pkgver)|;
         " configure.ac
  sed -i 's|INCLUDES|AM_CPPFLAGS|;
         ' {contrib/{drbd-outdate-peer,ipfail,mlock},cts,heartbeat,lib/{apphb,hbclient,plugins/{HB{auth,comm,compress},quorum{,d},tiebreaker}},membership/{ccm,quorumd},replace,telecom/apphbd,tools}/Makefile.am
}

build() {
  cd $srcdir/${_pkgname^}-3-0-STABLE-$pkgver
  setarch $CARCH ./bootstrap
  setarch $CARCH ./configure --prefix=/usr\
    --disable-fatal-warnings\
    --enable-static=no\
    --enable-valgrind\
    --libdir=/usr/lib\
    --localstatedir=/var\
    --sysconfdir=/etc
  setarch $CARCH make
}

package() {
  cd $srcdir/${_pkgname^}-3-0-STABLE-$pkgver
  setarch $CARCH make DESTDIR=$pkgdir install

  install -d $pkgdir/usr/lib/systemd/system
  install -Dm644 $srcdir/$pkgname.service $pkgdir/usr/lib/systemd/system
}

# vim:set ts=2 sw=2 et: