# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=linphone
pkgname=linphone-git
pkgver=r9466.8d21acd
pkgrel=1
pkgdesc="A Voice-over-IP phone"
arch=('i686' 'x86_64')
url="http://www.linphone.org/"
license=('GPL2')
depends=('alsa-lib' 'ffmpeg' 'gtk2' 'speex' 'libv4l' 'libglade' 'v4l-utils'
	 'libpulse' 'libxv' 'mediastreamer-git' 'ortp-git' 'bzrtp-git' 'bcg729' 'libsoup'
	 'belle-sip-git' 'libnotify' 'bcunit-git' 'bctoolbox-git')
makedepends=('pkg-config' 'perl-xml-parser' 'intltool' 'sgmltools-lite' 'git')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
optdepends=('pulseaudio')
options=('!emptydirs')
source=("${_pkgname}-${pkgver}::git+https://github.com/BelledonneCommunications/linphone#branch=master")
sha256sums=('SKIP')

pkgver() {
  cd $_pkgname-$pkgver
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd $_pkgname-$pkgver
  ./autogen.sh
}

build() {
  cd $_pkgname-$pkgver
  export PKG_CONFIG=/usr/bin/pkg-config
  unset SGML_CATALOG_FILES
  ./configure --prefix=/usr --disable-static --enable-ipv6 --enable-video \
	--enable-alsa --enable-pulseaudio --disable-artsc --disable-strict \
	--libexecdir=/usr/lib/$_pkgname \
	--enable-external-mediastreamer \
	--enable-external-ortp \
	--enable-zrtp
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}