# Contributor (Arch)     : Serge Zirukin <ftrvxmtrx@gmail.com>
# Contributor (Arch)     : Sergei Lebedev <superbobry@gmail.com
# Contributor (Arch)     : serp <serp256 at gmail dot com>
# Maintainer  (Parabola) : Aurélien DESBRIÈRES <aurelien@hackers.camp> 

pkgname="ocaml-lwt"
pkgver=2.4.4
pkgrel=1
pkgdesc="A library for cooperative threads in OCaml"
arch=('i686' 'x86_64' 'mips64el')
url="http://ocsigen.org/lwt/"
license=('LGPL')
depends=('ocaml>=3.12.0' 'ocaml-compiler-libs'
         'ocaml-react' 'ocaml-text' 'ocaml-ssl' 'libev' 'glibc')
makedepends=('ocaml-findlib')
source=(https://github.com/ocsigen/lwt/archive/$pkgver.tar.gz)
#source=(http://ocsigen.org/download/lwt-$pkgver.tar.gz)
options=(!strip !makeflags staticlibs)
build() {
  cd "$srcdir/${pkgname/ocaml-/}-$pkgver"

  echo '<src/top/*.*>: use_compiler_libs' >> _tags
  # What requires what?
  # --enable-glib      glibc
  # --enable-react     ocaml-react
  # --enable-ssl       ocaml-ssl
  # --enable-text      ocaml-text
  # --enable-toplevel  ocaml-compiler-libs

  ./configure --enable-react \
              --enable-glib \
              --enable-ssl \
              --enable-text \
              --enable-toplevel \
              --disable-debug \
              --prefix /usr \
              --destdir $pkgdir
  make || return 1
}


package() {
  cd "$srcdir/${pkgname/ocaml-/}-$pkgver"

  export OCAMLFIND_DESTDIR="$pkgdir/$(ocamlfind printconf destdir)"

  mkdir -p "$OCAMLFIND_DESTDIR/stublibs"
  make install
  install -Dm 644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}