# Maintainer: Márcio Silva <coadde@lavabit.com>

pkgname=openipmi
_pkgname1=${pkgname::4}
_pkgname2=${pkgname:4}
_pkgname=${_pkgname1^}${_pkgname2^^}
pkgver=2.0.19
_pkgver=${pkgver::3}
pkgrel=1
pkgdesc="Allow access to platform information using Intelligent Platform Management Interface (${_pkgname2^^})"
arch=(
  i686
  x86_64
  mips64el
)
url=http://sourceforge.net/projects/$pkgname/
depends=(
  glib
  net-snmp
  #python2
  swig
  tcl
)
makedepends=(
  dia
  ghostscript-libre
  texlive-bibtexextra
)
options=(!libtool)
license=(
  BSD-new
  GPL2
  LGPL2.1
)
source=http://downloads.sourceforge.net/project/$pkgname/$_pkgname' '$_pkgver' 'Library/$_pkgname-$pkgver.tar.gz
sha512sums=ee95eb64b7cde3f22c8444a5f8e3172808b0bb9a3a7034c1302c5f568c1cc0852a44ccc836924267b5f9901f7a8a3f4c66272cc0b663aa55689d7529841217cb

prepare() {
  cd $srcdir/$_pkgname-$pkgver
  sed -i '/on Linux/ s|Linux|GNU/Linux|' $(grep -rl Linux)
}

build() {
  cd $srcdir/$_pkgname-$pkgver
  setarch $CARCH ./configure --prefix=/usr\
    --disable-static
  setarch $CARCH make
}

package() {
  cd $srcdir/$_pkgname-$pkgver
  install -d $pkgdir/usr/bin
  setarch $CARCH make DESTDIR=$pkgdir install
}

# vim:set ts=2 sw=2 et: