# Contributor (Arch): Tom <tomgparchaur@gmail.com>
# Maintainer        : Omar Vega Ramos <ovruni@gnu.org.pe>
# Based on a quantax contribution for irssi-otr

pkgname=xchat-otr
pkgver=0.3
pkgrel=2.1
pkgdesc="Off-the-Record Messaging (OTR) plugin for the XChat IRC client"
arch=('i686' 'x86_64')
url="http://irssi-otr.tuxfamily.org/"
license=('GPL')
depends=('xchat' 'libotr3')
makedepends=('cmake' 'pkgconfig' 'python')
source=("ftp://download.tuxfamily.org/irssiotr/${pkgname}-${pkgver}.tar.gz"
	'http://xchat.org/docs/xchat-plugin.h')
md5sums=('49706959af491c721a8a5a62bd224670'
         '5ee7da5abedc78a30b90e737370d8f0b')

prepare() {
  mkdir -p ${srcdir}/${pkgname}-${pkgver}/xchat
  mv ${srcdir}/xchat-plugin.h ${srcdir}/${pkgname}-${pkgver}/xchat
}

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  find ${srcdir}/${pkgname}-${pkgver} -type f -print0 | xargs -0 sed -i 's@libotr/@libotr3/@g'
  cmake -DXCHAT_INCLUDE_DIR=${srcdir}/${pkgname}-${pkgver} -DCMAKE_INSTALL_PREFIX=/usr . -DLIBOTR_LIBRARY=/usr/lib/libotr3.so
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install
  install -Dm644 README.xchat ${pkgdir}/usr/share/doc/${pkgname}/README.xchat
  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  rm -r ${pkgdir}/usr/share/doc/irssi-otr/
}