# Maintainer: Luke R. <g4jc@openmailbox.org> GPG: rsa4096/3EAE8697 
# Contributor (Arch): chrisl echo archlinux@c2h0r1i2s4t5o6p7h8e9r-l3u4n1a.com|sed 's/[0-9]//g'
# Contributor (Arch): Dany Martineau <dany.luc.martineau gmail.com>
# Contributor (Arch):  Stefan Clarke <fm0nk3y@yahoo.co.uk>

pkgname=xwinwrap
pkgver=20090215
pkgrel=1
pkgdesc="Shantanu Goel's patched xwinwrap. Xwinwrap is a utility, originally written by David Reveman/Novell, that will embed movies or screensavers as wallpaper. It is under a custom but permissive license."
[ "$CARCH" = "i686"   ] && ARCH=x86
[ "$CARCH" = "x86_64" ] && ARCH=x86_64
arch=(i686 x86_64)
url="http://tech.shantanugoel.com/projects/linux/shantz-xwinwrap"
license=('custom')
depends=('libxext' 'libxrender')
provides=('xwinwrap')
conflicts=('xwinwrap')
makedepends=('make')
validpgpkeys=('CB6E213A349B8DF9E96B622AC3F4FFCF3EAE8697') # PKGBUILD Maintainer's key
source=('https://bazaar.launchpad.net/~shantanu-goel/xwinwrap/devel/download/shantanu.goel%40gmail.com-20081018102932-9a50c8t7sa40ihkx/makefile-20080824172326-ckr2ck4kremspqqc-1/Makefile'
'https://bazaar.launchpad.net/~shantanu-goel/xwinwrap/devel/download/shantanu.goel%40gmail.com-20090215112845-2e2mb6202tzwa4vb/xwinwrap.c-20080824172326-ckr2ck4kremspqqc-2/xwinwrap.c'
'PKGBUILD'
'PKGBUILD.sig')
sha512sums=('4465aa846bf7cda3826e2d01a1c768de9099cbefbfa0fa891c46b056e369362b9e372546ed5b535fa89e6fdae6eb903f10750c4535408794be269eb7db40aae0'
            'e9d9a7489e11d5c6eee86970df4b5d6ee2cb87b512dc80bce2edcc429757371562495de3a98f0cd16a9cba8423e0c37efad9b925f94e12bf287cf6f94d49ee1c'
	    'SKIP'
	    'SKIP')
whirlpoolsums=('4b86c028b960d59f1c97545173fe51bb6d159cbeb0bd141a99c9debaa64f056ae08f5541a058a787d331dcdfa78c406ed242a426c1f4390dbf8afa3e4537fdea'
               '3186c04e3822c1655e22a00253e1bf4980f3065a026074647f60b38b330db9e13fd5e3f15c5f5f4a3bd6c286460054cddf2ad43b371798ef96d741f648309785'
	       'SKIP'
	       'SKIP')

prepare(){
sed -i "s/-lX11/-mtune=generic -O2 -pipe -fstack-protector-strong --param=ssp-buffer-size=4 -D_FORTIFY_SOURCE=2 -lX11/" Makefile ## Stronger compilation security
head -n43 xwinwrap.c >> LICENSE
}

build() {
  cd ${srcdir}
  if [ "$CARCH" == "i686" ]; then
    make all32 || return 1
  else
    make all64 || return 1
  fi
}
package() {
  cd ${srcdir}
  if [ "$CARCH" == "i686" ]; then
    install -D -m0755 ${srcdir}/i386/xwinwrap ${pkgdir}/usr/bin/xwinwrap && install -D LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE" || return 1
  else
    install -D -m0755 ${srcdir}/x86_64/xwinwrap ${pkgdir}/usr/bin/xwinwrap && install -D LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE" || return 1
  fi
}