# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Maintainer: Jonas Heinrich <onny@project-insanity.org>

pkgname=opentracker
pkgver=20120911
pkgrel=2
pkgdesc='An open and free bittorrent tracker (open mode)'
arch=('i686' 'x86_64')
url='http://erdgeist.org/arts/software/opentracker/'
license=('custom:Beer' 'GPL')
makedepends=('libowfat' 'cvs')
depends=('bash' 'zlib')
backup=('etc/opentracker/config')
source=('opentracker.rc'
'opentracker.service'
'license.txt')
md5sums=('390bde9d010e79ab1309c02dcf9972e8'
'3c638b71d5ecb65fb7964796975b2078'
'865211941e882c0aff5d36a22ac9efaa')

_cvsroot=':pserver:anoncvs@cvs.erdgeist.org:/home/cvsroot'
_cvsmod='opentracker'

mksource() {
    pushd "${srcdir}"
	msg 'Connecting to CVS server....'
	if [ -d ${_cvsmod}/CVS ]; then
		cd ${_cvsmod}
	    cvs -z3 update -d
	else
		cvs -z3 -d ${_cvsroot} co -f ${_cvsmod}
		cd ${_cvsmod}
	fi

	msg 'CVS checkout done or server timeout'
    popd

    tar czf ${pkgname}-${pkgver}.tar.gz ${_cvsmod}/
}

build() {
	cd "${srcdir}/${_cvsmod}"
	msg 'Starting make...'

	sed	-e 's|# tracker.rootdir /usr/local/etc/opentracker|tracker.rootdir /etc/opentracker|' \
		-e 's|# access.stats 192.168.0.23|access.stats 127.0.0.1|' \
		-i opentracker.conf.sample

# See Makefile for available features
	make PREFIX=/usr \
         LIBOWFAT_HEADERS=/usr/includes \
         LIBOWFAT_LIBRARY=/usr/lib \
         FEATURES="-DWANT_SYSLOGS -DDEBUG_HTTPERROR"
}

package(){
	cd "${srcdir}/${_cvsmod}"

	install -D -m 755 opentracker $pkgdir/usr/bin/opentracker
	install -D -m 644 opentracker.conf.sample $pkgdir/etc/opentracker/config
	install -D -m 644 $srcdir/license.txt $pkgdir/usr/share/licenses/opentracker/license.txt

  # create /etc/rc.d/opentracker
  mkdir -p "$pkgdir/etc/rc.d/"
  install -m 755 "$srcdir/opentracker.rc" "$pkgdir/etc/rc.d/opentracker"

  # Create opentracker service
  mkdir -p "$pkgdir/usr/lib/systemd/system/"
  install -m 644 "$srcdir/opentracker.service" "$pkgdir/usr/lib/systemd/system/"
}